《消除隐藏线》解题报告

《消除隐藏线》解题报告
【题目来源】
湖南省首届“湘邮科技杯”大学生程序设计大赛，数据范围有改动
【题目描述】
在计算机辅助设计(CAD)中，有一个经典问题：消除隐藏线（被其它图形遮住的线段）。

你需要设计一个软件，帮助建筑师绘制城市的侧视轮廓图。

为了方便处理，限定所有的建筑物都是矩形的，而且全部建立在同一水平面上。

每个建筑物用一个三元组表示(L i,H i,R i)其中L i和R i分别是建筑物i 的左右边缘坐标，H i是建筑物i的高度。

下面左图中的建筑物分别用如下三元组表示：
(1,11,5),(2,6,7),(3,13,9),(12,7,16),(14,3,25),(19,18,2 2),(23,13,29),(24,4,28)
下面右图中的城市侧视轮廓线用如下的序列表示：
(1,11,3,13,9,0,12,7,16,3,19,18,22,3,23,13,29,0)
【输入格式】
输入文件中包含一系列的建筑物三元组。

建筑物的坐标都是正整数且不大于109。

建筑物的数目不会超过10000。

每行只有一个三元组。

三元组的每个元素之间用一个空格分开。

三元组按照L i排序，即左边缘坐标最小的建筑物三元组会出现在输入文件的第一行。

【输出格式】
输出文件中包含一行描述轮廓线的数值序列，其中偶元素代表轮廓线的延伸高度，奇元素代表轮廓线顶点的水平坐标，如上面的图例所示。

【输入样例】
1 11 5
2 6 7
3 13 9
12 7 16
14 3 25
19 18 22
23 13 29
24 4 28
【输出样例】
1 11 3 13 9 0 1
2 7 16
3 19 18 22 3 23 13 29 0
【题目分析】
本题其实是矩形覆盖问题的特殊情形——固定了矩形的下边界。

本题可以使用矩形切割或者离散化加上线段树解决，但是前者的时间复杂度在最坏情况下可能达到O(n3)1，而后者的编程实现比较复杂。

本文将介绍一种时间复杂度稳定在O(nlogn)，且编程比较简单的分治算法。

这种算法的思路是：要求n个矩形的轮廓，先将这n个矩形分成两个大小相等的部分，分别求其轮廓，然后再将这两个轮廓合并。

规模为1的问题可以直接解决。

具体来说，如果这个矩形的三元组表示为(L,H,R)，那么其轮廓为(L,H,R,0)。

对于规模为k的问题，假设得到了两个规模为k/2的轮廓，分别为A和B，我们如何得到合并后的轮廓C？首先，容易证明轮廓C的每一个横坐标，都来源于轮廓A和B的横坐标，而不会产生新的坐标值。

因此，我们只需计算A和B 1具体分析参见2004年集训队论文：薛矛《解决动态统计问题的两把利刃——剖析线段树与矩形切割》
中所有涉及到的横坐标在C 中的高度。

由于轮廓C 中的横坐标值要求有序，我们可以仿照归并排序的方法，用两个指针扫描轮廓A 和B 。

具体的方法是，设指针i 指向轮廓A 的当前横坐标，指针j 指向轮廓B 的当前横坐标。

如果指针i 指向的横坐标较小，那么将这一横坐标加入到C 中，且在C 中的高度为A 中第i 个横坐标对应的高度与B 中第j-1个横坐标对应的高度的最大值，然后将指针i 向后移一位；指针j 指向的横坐标较小的情况则类似处理。

如果两个指针指向的横坐标相同，此时只需将这一横坐标加入到C 中一次，且高度为两指针指向高度的最大值，然后将两指针同时向后移一位。

最后，需要扫描一遍轮廓C ，将相邻的高度相同的横坐标合并。

分析时间复杂度，设T(n)表示解决规模为n 的问题需要的时间，那么有
)()2
(2)(n O n T n T +=。

解此递归方程，得到T(n)=O(nlogn)。

空间方面，由于递归的层数为O(logn)，每一层需要保存O(n)的空间，所以总的空间复杂度为O(nlogn)。

【性能分析】
时间复杂度：O(nlogn)
空间复杂度：O(nlogn)
编程复杂度：低
【总结】
本题可以采用多种方法解决，本文介绍的分治方法的优势在于：编程简单、时间复杂度低。

【源代码】见附件remove.pas
program remove;
const maxn=10000;
type building=record{建筑类型}
f,t,h:longint;
end;
answer=record{轮廓类型}
tot:longint;
x,y:array[0..2*maxn+1] of longint;
end;
var n:longint;
b:array[1..maxn] of building;
o:answer;
procedure init;{读入数据}
begin
n:=0;
while not seekeof do begin
inc(n);
with b[n] do readln(f,h,t);
end;
end;
procedure doing(l,r:longint);{求从l到r的所有矩形的轮廓}
var m,i,j:longint;
ta,tb:answer;
begin
if l=r then begin{递归边界}
o.tot:=2;
o.x[1]:=b[l].f;
o.y[1]:=b[l].h;
o.x[2]:=b[l].t;
o.y[2]:=0;
exit;
end;
{递归处理两个部分}
o.tot:=0;
m:=(l+r) div 2;
doing(l,m);
ta.tot:=o.tot;
for i:=0 to o.tot do begin
ta.x[i]:=o.x[i];
ta.y[i]:=o.y[i];
end;
doing(m+1,r);
tb.tot:=o.tot;
for i:=0 to o.tot do begin
tb.x[i]:=o.x[i];
tb.y[i]:=o.y[i];
end;
{合并两个轮廓}
o.tot:=0;
i:=1;
j:=1;
while (i<=ta.tot) and (j<=tb.tot) do
if ta.x[i]<tb.x[j] then begin
inc(o.tot);
o.x[o.tot]:=ta.x[i];
o.y[o.tot]:=ta.y[i];
if tb.y[j-1]>o.y[o.tot] then o.y[o.tot]:=tb.y[j-1]; if o.y[o.tot]=o.y[o.tot-1] then dec(o.tot);
inc(i);
end else
if ta.x[i]>tb.x[j] then begin
inc(o.tot);
o.x[o.tot]:=tb.x[j];
o.y[o.tot]:=tb.y[j];
if ta.y[i-1]>o.y[o.tot] then o.y[o.tot]:=ta.y[i-1];
if o.y[o.tot]=o.y[o.tot-1] then dec(o.tot);
inc(j);
end else begin
inc(o.tot);
o.x[o.tot]:=ta.x[i];
o.y[o.tot]:=ta.y[i];
if tb.y[j]>o.y[o.tot] then o.y[o.tot]:=tb.y[j]; if o.y[o.tot]=o.y[o.tot-1] then dec(o.tot);
inc(i);inc(j);
end;
while i<=ta.tot do begin
inc(o.tot);
o.x[o.tot]:=ta.x[i];
o.y[o.tot]:=ta.y[i];
if o.y[o.tot]=o.y[o.tot-1] then dec(o.tot);
inc(i);
end;
while j<=tb.tot do begin
inc(o.tot);
o.x[o.tot]:=tb.x[j];
o.y[o.tot]:=tb.y[j];
if o.y[o.tot]=o.y[o.tot-1] then dec(o.tot); inc(j);
end;
end;
procedure main;{主过程}
begin
fillchar(o,sizeof(o),0);
o.x[0]:=-1;
o.y[0]:=-1;
doing(1,n);
end;
procedure print;{输出结果}
var i:longint;
begin
with o do
for i:=1 to tot do begin
write(x[i],' ',y[i]);
if i=tot then writeln else write(' ');
end;
writeln;
end;
begin
init;
main;
print;
end.。