二级MSOffice高级应用Excel函数总结

V L O O K U P函数
参数说明
Lookup_value为需要在数据表第一列中进行查找的数值。

Lookup_value 可以为数值、引用或文本字符串。

Table_array为需要在其中查找数据的数据表。

使用对区域或区域名称的引用。

col_index_num为table_array 中查找数据的数据列序号。

col_index_num 为1 时，返回table_array 第一列的数值，col_index_num 为2 时，返回table_array 第二列的数值，以此类推。

如果col_index_num 小于1，函数VLOOKUP 返回错误值#VALUE!；如果col_index_num 大于table_array 的列数，函数VLOOKUP 返回错误值#REF!。

Range_lookup为一逻辑值，指明函数VLOOKUP 查找时是精确匹配，还是近似匹配。

如果为false或0 ，则返回精确匹配，如果找不到，则返回错误值#N/A。

如果range_lookup 为TRUE或1，函数VLOOKUP 将查找近似匹配值，也就是说，如果找不到精确匹配值，则返回小于lookup_value 的最大数值。

如果range_lookup 省略，则默认为近似匹配。

例如：
【第1套】
=VLOOKUP(D3,编号对照!$A$3:$C$19,2,FALSE)
【第5套】
=VLOOKUP(E3,费用类别!$A$3:$B$12,2,FALSE)
【第9套】
=VLOOKUP(D3,图书编目表!$A$2:$B$9,2,FALSE)
【第10套】
=VLOOKUP(A2,初三学生档案!$A$2:$B$56,2,0)
SUMPRODUCT函数
说明: 数组参数必须具有相同的维数，否则，函数SUMPRODUCT 将返回错误值#VALUE!。

函数SUMPRODUCT 将非数值型的数组元素作为0 处理。

含义：SUM:【数】求和；PRODUCT:【数】(乘)积20 is the product of 5 and 4.二十是五与四的乘积。

SUMPRODUCT:组合的汉语意思是:乘积之和。

在给定的几组数组中，将数组间对应的元素相乘，并返回乘积之和。

公式：=SUMPRODUCT(B2：C4*D2：E4)
结果：两个数组的所有元素对应相乘，然后把乘积相加，即3*2+4*7+8*6+6*7+1*5+9*3。

说明
1、SUMPRODUCT函数不支持“*”和“”通配符。

SUMPRODUCT函数不能象SUMIF、COUNTIF等函数一样使用“*”和“”等通配符，要实现此功能可以用变通的方法，如使用LEFT、RIGHT、ISNUMBER(FIND())或ISNUMBER(SEARCH())等函数来实现通配符的功能。

2、SUMPRODUCT函数多条件求和时使用“，”和“*”的区别：当拟求和的区域中无文本时两者无区别，当有文本时，使用“*”时会出错，返回错误值#VALUE!，而使用“，”时SUMPRODUCT函数会将非数值型的数组元素作为0 处理，故不会报错。

应用实例
一、基本功能：函数SUMPRODUCT的功能返回相应的区域或数组乘积二、用于多条件计数用数学函数SUMPRODUCT计算符合2个及以上条件的数据个数
注意：TRUE*1=1，FALSE*1=1*FALSE=0，TRUE*0=0*TRUE=0 。

数组中用分号分隔，表示数组是一列数组，分号相当于换行。

两个数组相乘是同一行的对应两个数相乘。

三、用于多条件求和对于计算符合某一个条件的数据求和，可以用SUM IF函数来解决。

如果要计算符合2个以上条件的数据求和，用SUMIF函数就不能够完成了。

这就可以用函数SUMPRODUCT。

用函数SUMPRODUCT 计算符合多条件的数据和，其基本格式是：
SUMPRODUCT（条件1*条件2*……，求和数据区域）考试题中，求和公式在原来的计数公式中，在相同判断条件下，增加了一个求和的数据区域。

也就是说，用函数SUMPRODUCT求和，函数需要的参数一个是进行判断的条件，另一个是用来求和的数据区域。

*1的解释
umproduct函数，逗号分割的各个参数必须为数字型数据，如果是判断的结果逻辑值，就要乘1转换为数字。

如果不用逗号，直接用*号连接，就相当于乘法运算，就不必添加*1。

例如：
【第1套】
=SUMPRODUCT(1*(订单明细表!E3:E262="《MS Office高级应用》"),订单明细表!H3:H262)
1
=SUMPRODUCT(1*(订单明细表!C350:C461="隆华书店"),订单明细表!H350:H461)
=SUMPRODUCT(1*(订单明细表!C263:C636="隆华书店"),订单明细表!H263:H636)/12
【第5套】
=SUMPRODUCT(1*(费用报销管理!D74:D340="北京市"),费用报销管理!G74:G340)
=SUMPRODUCT(1*(费用报销管理!B3:B401="钱顺卓"),1*(费用报销管理!F3:F401="火车票"),费用报销管理!G3:G401)
=SUMPRODUCT(1*(费用报销管理!F3:F401="飞机票"),费用报销管理!G3:G401)/SUM(费用报销管理!G3:G401) =SUMPRODUCT((费用报销管理!H3:H401="是")*(费用报销管理!F3:F401="通讯补助"),费用报销管理!G3:G401)
【第7套】
=SUMPRODUCT(1*(D3:D17="管理"),I3:I17)
=SUMPRODUCT(1*(D3:D17="管理"),M3:M17)
IF函数
IF函数，根据指定的条件来判断其"真"(TRUE)、"假"(FALSE)；根据逻辑计算的真假值，从而返回相应的内容。

用途：执行真假值判断
函数用法
1．IF函数的语法结构
IF(l ogical_test，value_if_true，value_if_false)
即：IF函数的语法结构：IF(条件,结果1,结果2)。

2．IF函数的功能
对满足条件的数据进行处理，条件满足则输出结果1，不满足则输出结果2。

可以省略结果1或结果2，但不能同时省略。

3．条件表达式
把两个表达式用关系运算符(主要有=，<>，>，<，>=，<=等6个关系运算符)连接起来就构成条件表达式。

4．IF函数嵌套的执行过程
如果按等级来判断某个变量，IF函数的格式如下：
IF(E2>=85,"优",IF(E2>=75,"良"，IF(E2>=60,"及格"，"不及格")))
函数从左向右执行。

首先计算E2>=85，如果该表达式成立，则显示“优”，如果不成立就继续计算
E2>=75，如果该表达式成立，则显示“良”，否则继续计算E2>=60，如果该表达式成立，则显示“及格”，否则显示“不及格”。

例如：
【第5套】
=IF(WEEKDAY(A3,2)>5,"是","否")
【第7套】
=ROUND(IF(K3<=1500,K3*3/100,IF(K3<=4500,K3*10/100-105,IF(K3<=9000,K3*20/100-555,IF(K 3<=35000,K3*25%-1005,IF(K3<=5500,K3*30%-2755,IF(K3<=80000,K3*35%-5505,IF(K3>80000,K3 *45%-13505))))))),2)
【第10套】
=IF(MOD(MID(C2,17,1),2)=1,"男","女")
=IF(F2>=102,"优秀",IF(F2>=84,"良好",IF(F2>=72,"及格",IF(F2>72,"及格","不及格"))))
=IF(F2>=90,"优秀",IF(F2>=75,"良好",IF(F2>=60,"及格",IF(F2>60,"及格","不及格"))))
【第10套】
=IF(MID(A3,4,2)="01","1班",IF(MID(A3,4,2)="02","2班","3班"))
SUMIFS函数
根据多个指定条件对若干单元格求和。

函数用法
SUMIFS(sum_range, criteria_range1,criteria1, [criteria_range2, criteria2], ...)
1）sum_range 是需要求和的实际单元格。

包括数字或包含数字的名称、区域或单元格引用。

忽略空白值和文本值。

2) criteria_range1为计算关联条件的第一个区域。

3) criteria1为条件1，条件的形式为数字、表达式、单元格引用或者文本，可用来定义将对criteria_range1参数中的哪些单元格求和。

例如，条件可以表示为32、“>32”、B4、"苹果"、或"32"。

4）criteria_range2为用于条件2判断的单元格区域。

5) criteria2为条件2，条件的形式为数字、表达式、单元格引用或者文本，可用来定义将对criteria_range2参数中的哪些单元格求和。

4）和5）最多允许127个区域/条件对，即参数总数不超255个。

【第9套】
=SUMIFS(销售订单!$H$3:$H$678,销售订单!$E$3:$E$678,A4,销售订单!$C$3:$C$678,1)
=SUMIFS(销售订单!$H$3:$H$678,销售订单!$E$3:$E$678,A4,销售订单!$C$3:$C$678,2)
=SUMIFS(销售订单!$H$3:$H$678,销售订单!$E$3:$E$678,A4,销售订单!$C$3:$C$678,3)
【第20套】
=SUMIFS(表1[销售额小计],表1[日期],">=2013-1-1",表1[日期],"<=2013-12-31")
=SUMIFS(表1[销售额小计],表1[图书名称],订单明细!D7,表1[日期],">=2012-1-1",表1[日期],"<=2012-12-31")
=SUMIFS(表1[销售额小计],表1[书店名称],订单明细!C14,表1[日期],">=2013-7-1",表1[日期],"<=2013-9-30")
=SUMIFS(表1[销售额小计],表1[书店名称],订单明细!C14,表1[日期],">=2012-1-1",表1[日期],"<=2012-12-31")/12
=SUMIFS(表1[销售额小计],表1[书店名称],订单明细!C14,表1[日期],">=2013-1-1",表1[日期],"<=2013-12-31")/SUMIFS(表1[销售额小计],表1[日期],">=2013-1-1",表1[日期],"<=2013-12-31")
--TEXT函数
将数值转换为按指定数字格式表示的文本。

函数用法
TEXT(value,format_text)
Value 为数值、计算结果为数字值的公式，或对包含数字值的单元格的引用。

Format_text 为"单元格格式"对话框中"数字"选项卡上"分类"框中的文本形式的数字格式。

例如：
【第8套】
="法律"&TEXT(MID(B3,3,2),"[DBNum1]")&"班"
"[DBNum1]"：数字格式转换
【第10套】
=- -TEXT(MID(C2,7,8),"0-00-00") 在二代身份证号码中提取出生年月；
例：
="1990-05-02"
DATEDIF函数
主要用于计算两日期相差年月日数，利用该函数可计算相差的天数、月数和年数。

DATEDIF(start_date,end_date,unit)
Start_date 为时间段内的起始日期。

End_date 为时间段内的结束日期。

Unit 为所需信息的返回类型。

”Y”时间段中的整年数。

”M”时间段中的整月数。

”D”时间段中的天数。

实例1：计算出生日期为1973-4-1人的年龄;
公式：=DATEDIF("1973-4-1",TODAY(),"Y") 结果：33 简要说明当单位代码为"Y"时,计算结果是两个日期间隔的年数.
【第10套】
=DATEDIF(- -TEXT(MID(C2,7,8),"0-00-00"),TODAY(),"y")
【第10套】
=DATEDIF(F2,H2,"YD")*24+(I2-G2)
MID函数
Mid是一个字符串函数，作用是从一个字符串中截取出指定数量的字符。

函数用法
MID(text,start_num,num_chars)
Text：字符串表达式，从中返回字符。

start_num：text 中被提取的字符部分的开始位置。

num_chars：要返回的字符数。

例：M=4100
A1=Mid(M,1,1) A1=4
A2=Mid(M,2,2) A2=10
例如：
【第2套】MID(A2,3,2)【第8套】MID(B3,3,2)【第10套】MID(C2,17,1)
MOD函数
是一个求余函数，即是两个数值表达式作除法运算后的余数。

函数用法
MOD(number,divisor)
Number 为被除数。

Divisor 为除数。

如果divisor 为零，函数MOD 返回值为原来number
例：MOD(-3, 2) 等于1(与后面的数符号相同)验证mod(3,-2)；MOD(3, -2) 等于-1(与后面的数符号相同)；mod （3，0）则出错#DIV/0!
例如：
【第10套】MOD(MID(C2,17,1),2)=1
RANK函数
rank函数是排名函数。

最常用的是求某一个数值在某一区域内的排名。

函数用法
rank函数语法形式: rank(number,ref,[order])
number 为需要求排名的那个数值或者单元格名称(单元格内必须为数字)
ref 为排名的参照数值区域
order的为0和1，默认不用输入，得到的就是从大到小的排名，若是想求倒数第几，order的值请使用1。

【第3套】=RANK(D2,$D$2:$D$21,0)
【第8套】=RANK(M3,M$3:M$102,0)
【第10套】="第"&RANK(F2,$F$2:$F$45)&"名"
LOOKUP函数
返回向量或数组中的数值。

函数 LOOKUP 有两种语法形式:向量和数组。

函数LOOKUP 的向量形式是在单行区域或单列区域(向量)中查找数值，然后返回第二个单行区域或单列区域中相同位置的数值;函数LOOKUP 的数组形式在数组的第一行或第一列查找指定的数值，然后返回数组的最后一行或最后一列中相同位置的数值。

函数LOOKUP 有两种语法形式:向量和数组。

使用方法
（1）向量形式：公式为= LOOKUP(lookup_value,lookup_vector,result_vector)
lookup_value：函数LOOKUP在第一个向量中所要查找的数值，它可以为数字、文本、逻辑值或包含数值的名称或引用；
lookup_vector：只包含一行或一列的区域lookup_vector 的数值可以为文本、数字或逻辑值；
result_vector：只包含一行或一列的区域其大小必须与lookup_vector 相同。

（2）数组形式：公式为= LOOKUP(lookup_value,array)
Array：包含文本、数字或逻辑值的单元格区域或数组它的值，用于与lookup_value 进行比较。

例如：LOOKUP(5.2,{4.2,5,7,9,10})=5。

注意：lookup_vector的数值必须按升序排列，否则函数LOOKUP不能返回正确的结果。

文本不区分大小写。

如果函数LOOKUP找不到lookup_value，则查找lookup_vector中小于或等于lookup_value的最大数值。

如果lookup_value小于lookup_vector中的最小值，函数LOOKUP返回错误值#N/A。

【第2套】
=LOOKUP(MID(A2,3,2),{"01","02","03"},{"1班","2班","3班"})
ROUND函数
EXCEL中的基本函数，作用按指定的位数进对数值进行四舍五入。

函数用法
ROUND(number,num_digits)
number，要四舍五入的数字。

num_digits，位数，按此位数对number 参数进行四舍五入。

【第7套】
=ROUND(IF(K3<=1500,K3*3/100,IF(K3<=4500,K3*10/100-105,IF(K3<=9000,K3*20/100-555, IF(K3<=35000,K3*25%-1005,IF(K3<=5500,K3*30%-2755,IF(K3<=80000,K3*35%-5505,IF(K3>8000 0,K3*45%-13505))))))),2)，
WEEKDAY函数
返回某日期的星期数。

在默认情况下，它的值为1(星期天)到7(星期六)之间的一个整数。

WEEKDA Y(serial_number，return_type)
serial_number 是要返回日期数的日期，它有多种输入方式：带引号的文本串(如2001/02/26)、序列号(如35825 表示1998 年1月30 日) 或其他公式或函数的结果(如DATEVALUE(2000/1/30))。

return_type为确定返回值类型的数字，
数字1 或省略，则1 至7 代表星期天到星期六，
数字2则1 至7 代表星期一到星期天，
数字3则0至6代表星期一到星期天。

实例=WEEKDAY(2001/8/28，2) 返回2(星期二)
=WEEKDAY(2003/02/23，3) 返回6(星期日)。

【第5套】=IF(WEEKDAY(A3,2)>5,"是","否")
MONTH函数
Month函数指返回一个 Variant (Integer)，其值为 1 到 12 之间的整数，表示一年中的某月。

函数用法
Month(date)
必要的date 参数，可以是任何能够表示日期的Variant、数值表达式、字符串表达式或它们的组合。

如果date 包含Null，则返回Null。

【第9套】
=MONTH($B$3:$B$678)
HOUR函数
Hour(time)
必要的time 参数，可以是任何能够表示时刻的Variant、数值表达式、字符串表达式或它们的组合。

如果time 包含Null，则返回Null。

返回一个Variant (Integer)，其值为0 到23 之间的整数，表示一天之中的某一钟点。

【第19套】
=HOUR(J2)
MINUTE函数
用途：返回时间值中的分钟，即介于0到59之间的一个整数。

语法：MINUTE(serial_number) 参数：Serial_number是一个时间值，其中包含着要查找的分钟数。

时间有多种输入方式:带引号的文本串(如"6:45 PM")、十进制数(如0.78125表示6:45 PM)或其他公式或函数的结果(如TIMEVaLUE("6:45 PM"))。

实例：公式“=MINUTE("15:30:00")”返回30，=MINUTE(0.06)返回26
=MINUTE(TIMEVaLUE("9:45 PM"))返回45。

【第19套】
MINUTE(J2)
LEFT函数
得到字符串左部指定个数的字符。

LEFT( string, n )
string 指定要提取子串的字符串。

n 指定子串长度返回值String。

例：如果A1=安徽省蚌埠市固镇县杨庙乡，则公式“=LEFT(A1,FIND("省",A1))”返回安徽省。

= Left("Hello World", 7) '返回"Hello W"。

【第5套】
=LEFT(C3,3)，表示取当前文字左侧的前三个字符
SUBTOTAL函数
语法: SUBTOTAL(function_num,ref1,ref2, ...)
Function_num 为1 到11(包含隐藏值)或101 到111(忽略隐藏值)之间的数字，指定使用何种函数在列表中进行分类汇总计算。

ref1……refn参数为要对其进行分类汇总计算的第1至29个命名区域或引用。

必须是对单元格区域的引用。

Function_num (包含隐藏值)为1到11之间的自然数，用来指定分类汇总计算使用的函数
【第9套】
=SUBTOTAL(109,B4:B11)
INT函数
将数值向下取整为最接近的整数。

函数用法
INT（number）
Number 需要进行向下舍入取整的实数。

所谓“向下舍入”就是当计算时，如果计算结果不为整数时，取小于该计算结果的整数
相反的，“向上舍入”就是计算结果不为整数时，取大于该计算结果的整数
【第16套】
=INT((TODAY()-I3)/365)
【第18套】
="第"&INT(1+(MONTH(A3)-1)/3)&"季度"
TRUNC函数
TRUNC函数返回以指定元素格式截去一部分的日期值。

TRUNC（number,[num_digits]）
Number 必需。

需要截尾取整的数字。

Num_digits 可选。

用于指定取整精度的数字。

Num_digits 的默认值为0（零）。

说明: TRUNC 和INT 类似，都返回整数。

TRUNC 直接去除数字的小数部分，而INT 则是依照给定数的小数部分的值，将其向小方向到最接近的整数。

INT 和TRUNC 在处理负数时有所不同：TRUNC(-4.3) 返回-4，而INT(-4.3) 返回-5，因为-5 是较小的数。

示例
【第19套】
=E2*(TRUNC((HOUR(J2)*60+MINUTE(J2))/15)+1)
=E2*TRUNC((HOUR(J2)*60+MINUTE(J2))/15)。