徐小明：趋势为王，结构修边的结构买点公式（加入对称周期）

徐小明：趋势为王，结构修边的结构买点公式（加入对称周
期）
网络大V徐小明的操作策略：趋势为王，结构修边市场经典理论，有些人认为很有用，但也有些人认为没用。

今天我们不是评价其理论好用与不好用。

我们来研究它的其中一个买点，就是MACD背离结构买点。

这个背离结构对于市场上很多人都熟识。

这类结构公式很多同时也很乱，应一些网友要求，今天发布一个完整且简单版公式给大家，顺便对于MACD使用注意点，作简单说明。

这次发布MACD公式，本人加了金死叉周期数，大家可以从对称角度去分析和估算。

通达信公式：
DIF:EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:EMA(DIF,9);
MACD:=(DIF-DEA)*2;
STICKLINE(MACD>0 && REF(MACD,1)<MACD, MACD,0,0,0),COLORRED;
STICKLINE(MACD>0 && REF(MACD,1)>MACD, MACD,0,0,0),COLORYELLOW;
STICKLINE(MACD<0 && REF(MACD,1)<MACD, MACD,0,0,0),COLORWHITE;
STICKLINE(MACD<0 && REF(MACD,1)>MACD, MACD,0,0,0),COLORGREEN;
{底部结构预警}
死叉:=CROSS(DEA,DIF);
N1:=BARSLAST(死叉),NODRAW;
{最近一次死叉的位置}
N2:=REF(BARSLAST(死叉),N1+1);
{倒数第二次死叉与倒数第一次死叉的区间}
N3:=REF(BARSLAST(死叉),N2+N1+2);
{倒数第三次死叉与倒数第二次死叉的区间}
CL1:=LLV(C,N1+1);
{最近一次死叉后，最低收盘价}
DIFL1:=LLV(DIF,N1+1);
CL2:=REF(CL1,N1+1);
{倒数第二次死叉与倒数第一次死叉之间的最低收盘价}
DIFL2:=REF(DIFL1,N1+1);
CL3:=REF(CL2,N1+1);
{倒数第三次死叉与倒数第二次死叉之间的最低收盘价}
DIFL3:=REF(DIFL2,N1+1);
PDIFL2:=IF(DIFL2>0,INTPART(LOG(DIFL2))-1,INTPART(LOG(-DIFL2))-1);
MDIFL2:=INTPART(DIFL2/POW(10,PDIFL2));
PDIFL3:=IF(DIFL3>0,INTPART(LOG(DIFL3))-1,INTPART(LOG(-DIFL3))-1);
MDIFL3:=INTPART(DIFL3/POW(10,PDIFL3));
MDIFB2:=INTPART(DIF/POW(10,PDIFL2));
MDIFB3:=INTPART(DIF/POW(10,PDIFL3));
直接底背离:=(CL1<CL2 ) AND (MDIFB2>MDIFL2) AND (MACD<0 AND REF(MACD,1)<0) AND MDIFB2<=REF(MDIFB2,1);
隔峰底背离:=(CL1<CL3 AND CL3<CL2 ) AND
(MDIFB3>MDIFL3) AND (MACD<0 AND REF(MACD,1)<0) AND MDIFB3<=REF(MDIFB3,1);
B:=直接底背离 OR 隔峰底背离;
BG:=((MDIFB2>REF(MDIFB2,1))*REF(直接底背离,1)) OR ((MDIFB3>REF(MDIFB3,1))*REF(隔峰底背离,1));
底背离消失:=(REF(直接底背离,1) AND DIFL1<=DIFL2 ) OR (REF(隔峰底背离,1) AND DIFL1<=DIFL3);
DRAWTEXT(TFILTER(B,MACD>0,1),(DIF+MACD),'钝化'),COLORYELLOW;
DRAWTEXT(TFILTER(底背离消失,B,1),(DIF+MACD),'消失'),COLORGREEN;
DRAWTEXT(TFILTER(BG,MACD>0,1),(DIF+MACD),'形成'),COLORRED;
{顶部结构预警}
金叉:=CROSS(DIF,DEA);
M1:=BARSLAST(金叉);
{最近一次金叉的位置}
M2:=REF(BARSLAST(金叉),M1+1);
{倒数第二次金叉与倒数第一次金叉的区间}
M3:=REF(BARSLAST(金叉),M2+M1+2);
{倒数第三次金叉与倒数第二次金叉的区间}
CH1:=HHV(C,M1+1);
{最近一次金叉后，最高收盘价}
DIFH1:=HHV(DIF,M1+1);
CH2:=REF(CH1,M1+1);
{倒数第二次金叉与倒数第一次金叉之间的最高收盘价}
DIFH2:=REF(DIFH1,M1+1);
CH3:=REF(CH2,M1+1);
{倒数第三次金叉与倒数第二次金叉之间的最高收盘价}
DIFH3:=REF(DIFH2,M1+1);
PDIFH2:=IF(DIFH2>0,INTPART(LOG(DIFH2))-
1,INTPART(LOG(-DIFH2))-1);
MDIFH2:=INTPART(DIFH2/POW(10,PDIFH2));
PDIFH3:=IF(DIFH3>0,INTPART(LOG(DIFH3))-
1,INTPART(LOG(-DIFH3))-1);
MDIFH3:=INTPART(DIFH3/POW(10,PDIFH3));
MDIFT2:=INTPART(DIF/POW(10,PDIFH2));
MDIFT3:=INTPART(DIF/POW(10,PDIFH3));
直接顶背离:=(CH1>CH2 ) AND (MDIFT2<MDIFH2) AND (MACD>0 AND REF(MACD,1)>0) AND MDIFT2>=REF(MDIFT2,1);
隔峰顶背离:=(CH1>CH3 AND CH3>CH2 ) AND (MDIFT3<MDIFH3) AND (MACD>0 AND REF(MACD,1)>0) AND MDIFT3>=REF(MDIFT3,1);
T:=直接顶背离 OR 隔峰顶背离;
TG:=((MDIFT2<REF(MDIFT2,1))*REF(直接顶背离,1)) OR ((MDIFT3<REF(MDIFT3,1))*REF(隔峰顶背离,1));
顶背离消失:=(REF(直接顶背离,1) AND DIFH1>=DIFH2 ) OR (REF(隔峰顶背离,1) AND DIFH1>=DIFH3);
DRAWTEXT(TFILTER(T,MACD<0,1),(DIF+MACD),'钝化'),COLORYELLOW;
DRAWTEXT(TFILTER(顶背离消失,T,1),(DIF+MACD),'消失'),COLORGREEN;
DRAWTEXT(TFILTER(TG,MACD<0,1),(DIF+MACD),'形成'),COLORGREEN;
QA:="MACD.DIF",COLORWHITE;
QB:="MACD.DEA",COLORCYAN;
上涨:=IF(QA>QB,QA,DRAWNULL);
NOTEXT上涨:上涨,COLORRED,LINETHICK1;
下跌:=IF(QA<QB,QA,DRAWNULL);
NOTEXT下跌:下跌,COLORLIGREEN,LINETHICK1;
NOTEXTWB:IF(QB<QA,QB,DRAWNULL),COLORMAGENTA,LI NETHICK1;
上涨周期:BARSLAST(QB>QA),NODRAW,COLORRED;
DRAWNUMBER(QB>QA AND REF(QB,1)<REF(QA,1),QB,REF(上涨周期,1)),COLORRED;
下跌周期:BARSLAST(QB<QA),NODRAW,COLORGREEN;
DRAWNUMBER(QB<QA AND REF(QB,1)>REF(QA,1),QB,REF(下跌周期,1)),COLORGREEN;
NOTEXTAAA:0,DOTLINE,COLORGRAY;
使用说明：（高手们，可以出门左转。

新手朋友可以看看）
MACD公式里存在着三个买卖点。

第一买卖点，股价偏离均线，红绿柱收缩后可以作为第一个买卖点。

这个买点可以说叫做偏离买卖点，特别要注意偏离率大的时候成功率才高。

第二买卖点是背离结构，就是本文公式。

这个背离买点成立原理就是因为前一波速度跟后一波速度起到变化。

简单说，一个篮球从高处掉地上后，会反弹，反弹后，又掉回地面。

这个过程能量慢慢衰减。

当做空动能减弱后，做多动能就增强。

此时趋势就能起到反转。

第三个买卖点就是金死叉，这个点多作为加减仓用，但也可以作为开仓或清仓点用，按实际使用吧！我的头条文章里有专门针对MACD金死叉作为买卖点使用成功率测试，有兴趣朋友可以去看看。

MACD使用，本人不多说，大家都非常熟识了。

此次发布公式，在原公式基础上，加上一个周期数据统计，可以让大家更直观地进行周期性对比。

喜欢技术文章朋友可以关注我哦！以后有好公式都发布给大家！（本章完）。