【EXCEL】提取数字方法

【EXCEL】提取数字
轻舟上逆
64位粉丝
1楼

〖问题〗有下边一串数据，如何才能将数字与字母分离
15.83m
2.4m
4pc
20m
15cm
15m
2.4m
1.34m


〖解法〗，B1输入：
=LOOKUP(9E+307,--LEFT(A1,ROW(INDIRECT("1:"&LEN(A1)))))
或简单的：
=-LOOKUP(0,-LEFT(A1,ROW($1:$1024)))



2007-9-19 14:17 回复

轻舟上逆
64位粉丝
2楼

15.83m
〖问题〗如果上面的数据变成如下，也就是数字前后都有字母，如何提取？
a2.4m
b4pc
c20m
ad15cm
ed15m
fg2.4m
dc1.34m



〖解法〗，B1输入：
=-LOOKUP(,-MID(A1,MIN(FIND({0;1;2;3;4;5;6;7;8;9},A1&1234567890)),ROW($1:$1024)))

或数组公式：
=-LOOKUP(,-RIGHT(LEFT(A1,MATCH(,-MID(A1,ROW($1:$1024),1))),ROW($1:$1024)))

2007-9-19 14:21 回复

轻舟上逆
64位粉丝
3楼

〖问题〗如果数字与文本混排，如何提取数字？如下：
A43B05E12D
B2F5GB306


〖解法〗，B1输入数组公式：
=SUM(MID("0"&A1,LARGE(ISNUMBER(-MID(A1,COLUMN(1:1),1))*COLUMN(1:1),COLUMN(1:1))+1,1)*10^COLUMN(1:1))/10

2007-9-19 14:37 回复

轻舟上逆
64位粉丝
4楼

A1单元格是125，B1单元格是3520617。如何从B1中将A1的125替换掉，在C1得出3067。

——————————————————————————————————————

〖解法〗
C1输入数组公式：
=SUM(MID(0&B1,LARGE(ISNA(MATCH(MID(B1,COLUMN(1:1),1),MID(A1,COLUMN(1:1),1),))*COLUMN(1:1),ROW(INDIRECT("1:"&LEN(B1))))+1,1)*10^ROW(INDIRECT("1:"&LEN(B1))))/10

2007-11-8 17:24 回复

轻舟上逆
64位粉丝
5楼

比如A1的数字是398，乘以一个数398*936=372528，在B1单元格里显示这个得数的前5位，重复数字不算，自动得出37258。这个公式如何设置？

——————————————————————————————————————
〖做法〗
=SUM(MID(A1*936,SMALL(IF(MATCH(MID(A1*936,ROW($1:$15),1),MID(A1*936,ROW($1:$15),1),)=ROW($1:$15),ROW($1:$15)),ROW($1:$5)),1)*10^(5-ROW($1:$5)))

2007-11-27 12:24 回复

轻舟上逆
64位粉丝
6楼

单元格A1是一个这样的算式：
30×200=6000
如何把乘号后面的200提取出来？

—————————————————————————————————————————
〖做法〗
=MID(A1,FIND("×",A1)+1,SUM(FIND({"×";"="},A1)*{-1;1})-1)
或
=REPLACE(REPLACE(A1,FIND("=",A1),99,),1,FIND("×",A1),)
或
=-LOOKUP(0,-MID(A1,FIND("×",A1)+1,ROW($1:$15)))

2007-11-27 13:51 回复

轻舟上逆
64位粉丝
9楼

如何提取一个数字的小数部份,并使之变成整数。
如：A1单元格是12.235 ，在B1变成235。

〖做法〗
B1输入：
=--MID(A1,FIND(".",A1)+1,15)
或
=--REPLACE(A1,1,FIND(".",A1),)

2007-12-3 13:34 回复
124.226.45.* 10

楼

黎永生 (1450022200392),如何提取出名字或者括号内的数字？

2008-9-10 10:16 回复
221.174.222.* 11楼

吧主好
为什么2楼的数组公式里的$1024改为$1022及以下时计算c20m时返回的是0而不是20?

2008-10-10 20:23 回复
221.174.222.* 12楼

补充11楼的问题
在11楼的情况下,如果计算c220m时却可以返回220,这到底是为什么呢?

2008-10-10 20:28 回复
222.130.251.* 13楼

闫建英1777929003王静1777900074刘娥1777000370李凯杰1741300082杜德，如何提取其中的所有数字，请教高手。编辑宏命令感激不尽！

2008-12-1 20:41 回复
124.114.89.* 14楼

134********
134********
134********
134********
134********
134********
134********
134********
134********
134********
134********
134********
134********
134********

2008-12-24 09:07 回复

luoke_zhiyu
0位粉丝
15楼

765210
97654210
987432
965410
98764321
875320
965410
98764321
98754320
987432
98754320
87653210
765210
98754320
98654310
98754320

2009-6-12 10:52 回复

excelfansno1
12位粉丝
16楼

这是吧主开的“讲义”贴，建议各位不要在此提问，如有问题需要解决，可另开新贴，好让广大学习者连贯看贴，不致乱了思路。

14楼：=IF(ISNUMBER(FIND({4,7},RIGHT(A1,4))),"",A1)

15楼：=RIGHT(A1,MIN(LEN(TRIM(RIGHT(SUBSTITUTE($A1,{5;6;7;8;9},REPT(" ",10)),10)))))
（这是刚从E吧里偷来的吧主的公式）

2009-11-25 00:44 回复

wshcw
29位粉丝
17楼

14楼:
=IF(COUNT(FIND({4;7},RIGHT(A1,4))),"",A1)