ANSYS隧道开挖模拟

!*定义相关位置参数
FINISH $/CLEAR
*SET,X1,-12 $*SET,Y1,-12 $*SET,W1,28.9 $*SET,H1,30.15 !*几何面2的位置参数
*SET,X2,-25 $*SET,Y2,-12 $*SET,W2,13 $*SET,H2,30.15 !*几何面3的位置参数
*SET,X3,16.9 $*SET,Y3,-12 $*SET,W3,13 $*SET,H3,30.15 !*几何面4的位置参数
*SET,X4,-25 $*SET,Y4,-30 $*SET,W4,54.9 $*SET,H4,18 !*几何面5的位置参数
*SET,TH,0.4 !*支护壳的厚度
*SET,LENGTH_Z,50 !*隧道深度
!*定义单元类型、实常数、材料属性
/PREP7 $ET,1,MESH200,2 $ET,2,MESH200,6 !*3-D线单元2节点、面单元4节点
ET,3,SHELL63 $ET,4,SOLID45 $R,1,TH !*壳的厚度
MP,EX,1,3.0E10 $MP,PRXY,1,0.2 $MP,DENS,1,2700 !*支护材料属性
MP,EX,2,2.5E9 $MP,PRXY,2,0.32 $MP,DENS,2,2200 !*剩余土体的材料属性
MP,EX,3,2.5E9 $MP,PRXY,3,0.32 $MP,DENS,3,2200.1 !*挖去土体的材料属性
!*创建隧道支护控制关键点
K,1,0,0 $K,2,0,3.85 $K,3,0.88,5.5 $K,4,2.45,6.15 $K,5,4.02,5.5 $K,6,4.9,3.85 $K,7,4.9,0
!*创建隧道支护线模型和被挖去的土体面
LARC,1,2,6,8.13 !*两端点，参考点，半径生成弧线
LARC,2,3,6,3.21 $LARC,3,4,6,2.22 $LARC,4,5,2,2.22
LARC,5,6,2,3.21 $LARC,6,7,2,8.13 $LARC,7,1,4,6
A,1,2,3,4,5,6,7 !*由7条线生成一个面
!*创建辅助面以及剩余土体的几何面
BLC4,X1,Y1,W1,H1 $BLC4,X2,Y2,W2,H2 !*创建面2和面3
BLC4,X3,Y3,W3,H3 $BLC4,X4,Y4,W4,H4 !*创建面4和面5
/PNUM,AREA,1 $APLOT
!*划分网格
AOVL,1,2,3,4,5 !*5个面OVERLAP布尔操作
NUMMRG,ALL,,,,LOW $NUMCMP,ALL !*合并重复元素并重新编号
$L,1,8 $L,7,9 $L,6,10 $L,2,11
LSEL,S,,,21,22,1 $LSEL,A,,,7 $ASBL,5,ALL !*用7,21,22三条线分割面
LSEL,S,,,21,24,3 $LSEL,A,,,1 $ASBL,7,ALL !*用1,21,24三条线分割面
LSEL,S,,,22,23,1 $LSEL,A,,,6 $ASBL,8,ALL !*用6,22,23三条线分割面
NUMMRG,ALL,,,,LOW $NUMCMP,ALL
LSEL,S,,,2,5,1 $LCCAT,ALL $LESIZE,ALL,,,3
LSEL,S,,,9,11,2 $LSEL,A,,,6 $LSEL,A,,,1 $LESIZE,ALL,,,8
LSEL,S,,,8,10,2 $LSEL,A,,,7 $LESIZE,ALL,,,12
LSEL,S,,,21,24,1 $LESIZE,ALL,,,10
TYPE,2 $ASEL,S,,,5,8,1 $AMESH,ALL
!*对其余的面进行网格划分
ASEL,S,,,1 $AMESH,1
LSEL,S,,,12,13,1 $LESIZE,ALL,,,8 $LSEL,S,,,15,18,1 $LESIZE,ALL,,,6
ASEL,S,,,2,3,1 $AMESH,ALL
LSEL,S,,,14 $LESIZE,ALL,,,24 $LSEL,S,,,19,20,1 $LESIZE,ALL,,,6
LSEL,S,,,15,17,2 $LSEL,A,,,8 $LCCAT,ALL $ASEL,S,,,4 $AMESH,ALL
LSEL,S,LCCA $LDELE,ALL
NUMMRG,ALL,,,,LOW $NUMCMP,ALL $ALLSEL
!*将支护的线模型拉伸成壳模型
K,1000,,,-LENGTH_Z $L,1,1000 !*定义一个辅助关键点和辅助线
/VIEW,1,1,1,1 $/REPLOT
LSEL,S,,,1,7,1 $ADRAG,ALL,,,,,,25 $GPLOT
TYPE,3 $REAL,1 $MAT,1
ASEL,S,LOC,Z,-25 $APLOT $LSEL,S,LOC,Z,-25 $LESIZE,ALL,,,10
MSHAPE,0,2D $MSHKEY,1 $AMESH,ALL !*映射网格划分
!*创建围

岩单元
ASEL,INVERT $APLOT
TYPE,4 $MAT,2 $ASEL,R,,,2,8,1 $EXTOPT,ESIZE,10,0 $VDRAG,ALL,,,,,,25
EXTOPT,ACLEAR,1 $ALLSEL !*源面网格不保存
!*待挖去部分岩石的实体
MAT,3 $VDRAG,1,,,,,,25 $EPLOT
NUMMRG,ALL,,,,LOW $NUMCMP,ALL $FINI
!*施加边界条件以及重力加速度
/SOLU $ANTYPE,STATIC
ASEL,S,LOC,X,X2 $ASEL,A,LOC,X,X2+W4 $DA,ALL,UX,0 $ALLS
ASEL,S,LOC,Y,Y4 $DA,ALL,UY,0 $ALLS
ASEL,S,LOC,Z,-LENGTH_Z $ASEL,A,LOC,Z,0 $DA,ALL,UZ,0 $ALLSEL
ACEL,,10 !*重力加速度10
!*设定分析选项
DELTIM,0.1,0.05,0.2 !*时间步长
AUTOTS,ON $PRED,ON !*使用自动时间步长并打开时间步长预测器
LNSRCH,ON $NLGEOM,ON !*打开线性搜索并打开大位移效果
NROPT,FULL $CNVTOL,F,,0.02,2,0.05 !*设定牛顿-拉普森迭代并设定力收敛条件
!*进行自重应力场计算
ESEL,S,TYPE,,3 $EKILL,ALL !*选择支护壳，然后将其杀死
ESEL,ALL $ESEL,S,LIVE !*选择活单元
NSLE,S $NSEL,INVERT $D,ALL,ALL !*约束被杀死单元节点
NSEL,ALL $ESEL,ALL $/PBC,ALL,,1 $GPLOT $SOLVE
!*开挖过程模拟
*DO,II,1,10,1
!*选择每个施工阶段挖去的岩土单元，然后将其杀死
ESEL,S,MAT,,3 $NSLE,S
NSEL,R,LOC,Z,0.1-(II-1)*5,-(5.1+(II-1)*5)
ESLN,R,1 $EKILL,ALL
!*选择挖去岩石单元对应的支护壳单元，将其激活
ESEL,S,TYPE,,3 $NSLE,S
NSEL,R,LOC,Z,0.1-(II-1)*5,-(5.1+(II-1)*5)
ESLN,R,1 $EALIVE,ALL
NSLE,S $DDELE,ALL,ALL
ESEL,ALL $ESEL,S,LIVE
NSLE,S $NSEL,INVERT $D,ALL,ALL
NSEL,ALL $ESEL,ALL $SOLVE
*ENDDO $FINI
! 开挖过程中的支护位移变化过程
/POST1 $/DEVICE,VECTOR,1 $ESEL,S,TYPE,,3
SET,1,LAST,1 $PLNSOL,U,Y,0,1 $SET,2,LAST,1 $PLNSOL,U,Y,0,1
SET,6,LAST,1 $PLNSOL,U,Y,0,1 $SET,11,U,Y,0,1 $PLNSOL,U,Y,0,1
!*开挖过程中支护等效应力的变化过程
/DEVICE,VECTOR,0
SET,1,LAST,1 $PLNSOL,S,EQV,0,1 $SET,2,LAST,1 $PLNSOL,S,EQV,0,1
SET,6,LAST,1 $PLNSOL,S,EQV,0,1 $SET,11,LAST,1 $PLNSOL,S,EQV,0,1