ansys转子-轴承系统的临界转速命令流
- 1、下载文档前请自行甄别文档内容的完整性，平台不提供额外的编辑、内容补充、找答案等附加服务。
- 2、"仅部分预览"的文档,不可在线预览部分如存在完整性等问题,可反馈申请退款(可完整预览的文档不适用该条件!)。
- 3、如文档侵犯您的权益，请联系客服反馈,我们会尽快为您处理(人工客服工作时间：9:00-18:30)。
/FILNAME,Critical Speed,0
/PREP7
L1=0.7 !转轴1的长度
D1=0.06 !转轴1的直径
L2=0.7 !转轴2的长度
D2=0.09 !转轴2的直径
L3=0.25 !转轴3的长度
D3=0.13 !转轴3的直径
L4=0.7 !转轴4的长度
D4=0.07 !转轴4的直径
M1=50 !转盘1的质量
JP1=4 !转盘1的极转动惯量
JD1=2 !转盘1的直径转动惯量
M2=20 !转盘2的质量
JP2=2 !转盘2的极转动惯量
JD2=1 !转盘2的直径转动惯量
!轴承1的特性参数
KYY1=1.764E9
KZZ1=1.764E9
!轴承2的特性参数
KYY2=3.264E9
KZZ2=3.264E9
ET,1,MASS21 !定义1号单元
ET,2,BEAM188 !定义2号单元
ET,3,COMBI214 !定义3号单元
KEYOPT,3,2,1 !设置3号单元关键字，轴承平行于Y-Z平面
!定义实常数
r,1,M1,M1,M1,JP1,JD1,JD1
r,2,M2,M2,M2,JP2,JD2,JD2
R,3,KYY1,KZZ1,
R,4,KYY2,KZZ2,
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,EX,1,,2.1E11
MPDATA,PRXY,1,,0.30
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,DENS,1,,7800
MPDATA,DAMP,1,,2E-5
!定义梁截面
SECTYPE, 1, BEAM, CSOLID, , 0
SECOFFSET, CENT
SECDATA,D1/2,25,10,0,0,0,0,0,0,0,0,0
SECTYPE, 2, BEAM, CSOLID, , 0
SECOFFSET, CENT
SECDATA,D2/2,25,10,0,0,0,0,0,0,0,0,0
SECTYPE, 3, BEAM, CSOLID, , 0
SECOFFSET, CENT
SECDATA,D3/2,25,10,0,0,0,0,0,0,0,0,0
SECTYPE, 4, BEAM, CSOLID, , 0
SECOFFSET, CENT
SECDATA,D4/2,25,10,0,0,0,0,0,0,0,0,0
!定义关键字
K,1,0,0,0
K,2,L1,0,0
K,3,L1+L2,0,0
K,4,L1+L2+L3,0,0
K,5,L1+L2+L3+L4,0,0
!通过关键点定义线
L,1,2
L,2,3
L,3,4
L,4,5
!设置单元总体尺寸
ESIZE,0.02
TYPE, 2
MAT, 1
REAL, 1
ESYS, 0
SECNUM, 1
LMESH,1
SECNUM, 2 !设置梁的截面号
LMESH, 2
SECNUM, 3
LMESH, 3
SECNUM, 4
LMESH, 4
!提取节点号
NM1=NODE(L1+L2,0,0)
NM2=NODE(L1+L2+L3+L4,0,0)
TYPE, 1
MAT, 1
REAL, 1
E,NM1
REAL, 2
E,NM2
N,,0,D1/2*1.5,0
N,,L1+L2+L3,D3/2*1.5,0
NZ11=NODE(0,0,0)
NZ12=NODE(0,D1/2*1.5,0)
NZ21=NODE(L1+L2+L3,0,0)
NZ22=NODE(L1+L2+L3,0.2,0)
TYPE, 3
REAL, 3
E,NZ11,NZ12
REAL, 4
E,NZ21,NZ22
/SOLU
antype,modal !设置分析类型为模态分析
MODOPT,QRDAMP,20,,,ON !提取20阶
MXPAND,20, !扩展20阶
!定义位移约束
D,ALL,UX
D,ALL,ROTX
D,NZ12,ALL
D,NZ22,ALL
!考虑陀罗效应
CORIOLIS,1, , ,1,0
!施加转速开始求解
omega,0
solve
omega,2000*2*3.1415/60
solve
omega,5000*2*3.1415/60
solve
omega,8000*2*3.1415/60
solve
omega,9000*2*3.1415/60
solve
omega,10000*2*3.1415/60
solve
omega,11000*2*3.1415/60
solve
/POST1
PRCAMP,,1,RPM !画坎贝尔图
PLCAMP,,1,RPM
!提取临界转速
*GET,CRIC1,CAMP,1,VCRI,,,
*GET,CRIC2,CAMP,2,VCRI,,,
*GET,CRIC3,CAMP,3,VCRI,,,
*GET,CRIC4,CAMP,4,VCRI,,,
*GET,CRIC5,CAMP,5,VCRI,,,