螺栓和法兰连接的接触分析(带预紧)

FINISH
/CLEAR,START
!************************************************************************
! 设置结构基本参数（参数可以按不同结构改变）
! 参数单位为： 力，N;长度，mm；弹性模量，N/mm^2；密度,tons/mm^3
!************************************************************************
*SET,RAD_I,1250/2 !主轴内半径
*SET,RAD_PANI,705 !圆盘内半径
*SET,RAD_O,2450/2 !主轴外半径
*SET,RAD_PANO,1830 !圆盘外半径
*SET,RAD_B,180/2 !螺栓孔径
*SET,M_BOLT,160 !螺栓最小直径
*SET,M_BH1,350+170+50 !螺栓在主轴方向长度
*SET,M_BH2,350+170+250 !螺栓在圆盘方向长度
*SET,M_NUT,280/2 !螺母大半径，六面体对角线长度
*SET,H_NUT,170 !螺母高
*SET,RAD_DRILL,2140/2 !螺栓节圆半径
*SET,RAD_M,750+150 !主轴内止口半径
*SET,H_M,18 !主轴内止口高度
*SET,RAD_BI,1950/2 !螺栓孔划平处内径
*SET,RAD_BO,2330/2 !螺栓孔划平处外径
*SET,RAD_BH,5 !螺栓孔划平处高度
*SET,F_RAD,45 !主轴与划平处过渡圆角半径
*SET,FH_RAD,1855/2 !螺栓孔划平处内半径
*SET,R_FILLET,125 !主轴过渡圆角
*SET,N,15 !螺栓分度数
*SET,KEY_W,290 !切向定位键宽
*SET,KEY_H,130 !切向定位键高
*SET,TH,200 !主轴轴壁最薄处厚度
*SET,FLANG_H1,350 !主轴法兰高度
*SET,FLANG_H2,350 !圆盘高度
*SET,H_SHAFT,350+490 !主轴上倾斜部分高度
*SET,H_SH,H_SHAFT+500 !主轴总高度
*SET,PI,ACOS(-1) !PI值
*SET,ELEMSIZE,60 !拉伸单元大小（可根据结构尺寸调节）
/GRAPHICS,POWER !Activate PowerGraphics
!************************************************************************
! 加载参数
!************************************************************************
*SET,DISP_B,0.75 !螺栓预紧的伸长量
*SET,ZMAX,H_SH !轴向方向最高处，加轴向力位置
*SET,F_EXT,22.9215E+5*12 !总的轴向力
*SET,F_EEF,30.827E+5*12 !半数磁极短路时在BOLT中引起的力
*SET,R_OUT,RAD_PANO !圆盘外半径
*SET,T_W,375 !圆盘被约束宽度
*SET,U_R,R_OUT-T_W !圆盘被约束处内半径
!************************************************************************
! 准备建立模型
!************************************************************************
/PREP7 !进入ANSYS前处理器
ET,1,185 !定义实体单元类型为

三维8节点Solid185块体单元
MP,EX,1,2.06E5 !定义主轴材料的弹性模量为2.06*10^5 MPa
MP,NUXY,1,0.29 !定义主轴材料的泊松比为0.29
MP,DENS,1,7.85E-9 !定义主轴材料的密度为7.85*10^(-9) tons/mm^3

MP,EX,2,2.06E5 !定义圆盘材料的弹性模量为2.06*10^5 MPa
MP,NUXY,2,0.29 !定义圆盘材料的泊松比为0.29
MP,DENS,2,7.85E-9 !定义圆盘材料的密度为7.85*10^(-9) tons/mm^3

MP,EX,3,2.06E5 !定义螺栓和螺母材料的弹性模量为2.06*10^5 MPa
MP,NUXY,3,0.29 !定义螺栓和螺母材料的泊松比为0.29
MP,DENS,3,7.85E-9 !定义螺栓和螺母材料的密度为7.85*10^(-9) tons/mm^3

MP,MU,4,0.15 !定义接触磨擦系数为材料4

!************************************************************************
! 建立结构关键点
!************************************************************************
K,1,RAD_I,0,H_M !主轴内半径，0，主轴内止口高度
K,2,RAD_M,0,0 !主轴内止口半径，0，0
K,3,RAD_I+TH,0,0 !主轴内半径+主轴轴壁最薄处厚度，0，0
K,4,RAD_O,0,0 !主轴外半径，0，0
K,5,RAD_O,0,FLANG_H1 !主轴外半径，0，主轴法兰高度
K,6,RAD_M,0,FLANG_H1 !主轴内止口半径，0，主轴法兰高度
K,7,RAD_I+TH,0,FLANG_H1 !主轴内半径+主轴轴壁最薄处厚度，0，主轴法兰高度
K,8,RAD_I+TH,0,H_SHAFT !主轴内半径+主轴轴壁最薄处厚度，0，主轴上倾斜部分高度
K,9,RAD_I,0,H_SHAFT !主轴内半径，0，主轴上倾斜部分高度
K,10,RAD_I,0,FLANG_H1 !主轴内半径，0，主轴法兰高度
K,11,RAD_M,0,H_M !主轴内止口半径，0，主轴内止口高度
K,12,RAD_I+TH,0,H_SH !主轴内半径+主轴轴壁最薄处厚度，0，主轴总高度
K,13,RAD_I,0,H_SH !主轴内半径，0，主轴总高度
K,14,RAD_BI,0,RAD_BH !螺栓孔划平处内径，0，螺栓孔划平处高度
K,15,RAD_BO,0,RAD_BH !螺栓孔划平处外径，0，螺栓孔划平处高度
K,16,RAD_BI,0,0 !螺栓孔划平处内径，0，0
K,17,RAD_BO,0,0 !螺栓孔划平处外径，0，0
K,18,RAD_BI,0,FLANG_H1 !螺栓孔划平处内径，0，主轴法兰高度
K,19,RAD_BO,0,FLANG_H1 !螺栓孔划平处外径，0，主轴法兰高度
K,20,RAD_I+TH+F_RAD,0,FLANG_H1 !主轴内半径+主轴轴壁最薄处厚度+主轴与划平处过渡圆角半径，0，主轴法兰高度
K,21,FH_RAD,0,0 !螺栓孔划平处内半径，0，0
K,22,FH_RAD,0,FLANG_H1+H_SHAFT !螺栓孔划平处内半径，0，主轴法兰高度+主轴上倾斜部分高度
K,23,FH_RAD,0,FLANG_H1

!栓孔划平处内半径，0，主轴法兰高度
!************************************************************************
! 通过关键点连线
!************************************************************************
L,8,20 !(主轴内半径+主轴轴壁最薄处厚度，0，主轴上倾斜部分高度)(主轴内半径+主轴轴壁最薄处厚度+主轴与划平处过渡圆角半径，0，主轴法兰高度)
L,20,5 !(主轴内半径+主轴轴壁最薄处厚度+主轴与划平处过渡圆角半径，0，主轴法兰高度)(主轴外半径，0，主轴法兰高度)
L,21,22 !(螺栓孔划平处内半径，0，0)(螺栓孔划平处内半径，0，主轴法兰高度+主轴上倾斜部分高度)
LFILLET,1,2,125 !Preprocessor-Modeling-Create-Lines-Line Fillet-拾取1#和2#线输入倒角值125-Ok

LSTR,1,10 !(主轴内半径，0，主轴内止口高度)(主轴内半径，0，主轴法兰高度)
LSTR,10,9 !(主轴内半径，0，主轴法兰高度)(主轴内半径，0，主轴上倾斜部分高度)
LSTR,9,13 !(主轴内半径，0，主轴上倾斜部分高度)(主轴内半径，0，主轴总高度)
LSTR,13,12 !(主轴内半径，0，主轴总高度)(主轴内半径+主轴轴壁最薄处厚度，0，主轴总高度)
LSTR,12,8 !(主轴内半径+主轴轴壁最薄处厚度，0，主轴总高度)(主轴内半径+主轴轴壁最薄处厚度，0，主轴上倾斜部分高度)
LSTR,8,9 !(主轴内半径+主轴轴壁最薄处厚度，0，主轴上倾斜部分高度)(主轴内半径，0，主轴上倾斜部分高度)

LSTR,8,24 !(主轴内半径+主轴轴壁最薄处厚度，0，主轴上倾斜部分高度)()

LSTR,1,11 !(主轴内半径，0，主轴内止口高度)(主轴内止口半径，0，主轴内止口高度)
LSTR,11,2 !(主轴内止口半径，0，主轴内止口高度)(主轴内止口半径，0，0)
LSTR,2,21 !(主轴内止口半径，0，0)(螺栓孔划平处内半径，0，0)
LSTR,21,4 !(螺栓孔划平处内半径，0，0)(主轴外半径，0，0)
LSTR,4,5 !(主轴外半径，0，0)(主轴外半径，0，主轴法兰高度)
LSTR,10,23 !(主轴内半径，0，主轴法兰高度)(栓孔划平处内半径，0，主轴法兰高度)
LSTR,5,23 !(主轴外半径，0，主轴法兰高度)(栓孔划平处内半径，0，主轴法兰高度)
LPTN,ALL !Preprocessor-Modeling-Operate-Booleans-Partition-Lines(pick all)-Ok

!布尔操作：将所有的线相交，这样可以让线与线之间互相共享连接，效果等同于粘接
!**************************************

**********************************
! 通过线建立结构的剖面，为旋转拉伸生成体作准备
!************************************************************************
AL,7,8,9,10
AL,1,22,21,16,6,10
AL,5,11,12,13,18,16
A,5,4,21,23
!************************************************************************
! 清除建模过程中多余的点和线
!************************************************************************
ALLS !提示：ALLSEL的缩写，所有ANSYS命令均可以只写前4个字母
ASEL,ALL !选择所有面
LSLA,U !反选线，即选择了和面无关的线
LDELE,ALL,,,1 !删除这些无用的线

ALLS
LSEL,ALL
KSLL,U
KDELE,ALL !删除无用的点
!************************************************************************
! 旋转剖面生成体
!************************************************************************
ALLS
CSYS,1 !转换到极坐标系

KGEN,2,1,,,,N,,,0
L,1,3 !生成拉伸路径弧

VDRAG,ALL,,,,,,2 !沿生成的线拉伸面生成体
!************************************************************************
! 通过布尔操作挖出螺栓孔和定位键槽
!************************************************************************
CSYS,0
CYL4,,,RAD_BI,,RAD_BO,,RAD_BH
VSBV,4,5
CYL4,RAD_DRILL,0,RAD_B,,,,FLANG_H1+100
CSYS,1
VGEN,,4,,,,N,,,,1
VSBV,6,4
WPRO,N,,
CSYS,4
VSYMM,Y,ALL,,,,0,0
WPRO,-N,,
CSYS,0
RECTNG,0,RAD_O+100,0,KEY_W/2,
VSEL,ALL
ASLV
ASEL,INVERT
VEXT,ALL,,,0,0,KEY_H,,,,
ALLS
VPTN,ALL
VDELE,11,,,1
VDELE,12,,,1
VDELE,15,,,1
VDELE,16,,,1
VDELE,18,,,1

WPOFF,0,KEY_W/2,0
WPRO,,90
VSBW,ALL
WPCSYS,-1,0
WPOFF,0,0,KEY_H
VSBW,ALL
WPCSYS,-1,0

CSYS,0
CYL4,,,RAD_BI,,RAD_BO,,FLANG_H1

VPTN,ALL
VDELE,33,,,1

WPOFF,0,0,RAD_BH
VSBW,ALL
WPOFF,0,0,-RAD_BH
!************************************************************************
! 创建下圆盘
!************************************************************************
CYLIND,RAD_PANI,RAD_PANO,0,-FLANG_H2,0,2*N,
CYL4,RAD_DRILL,0,RAD_B,,,,FLANG_H2+100
CSYS,1
VGEN,,16,,,,N,-FLANG_H2,,,1
VSBV,15,16
!************************************************************************
! 创建各部件的体积组件，以便于选择
!************************************************************************
VSEL,S,LOC,Z,0,H_SH+100 !通过坐标位置选择实体
CM,SHAFT,VOLU !将轴命名为SHAFT
ALLS
VSEL,S,LOC,Z,0,-FLANG_H2-100 !通过坐标位置选择实体
CM,PAN,VOLU !将圆盘命名为PAN
ALLS
!************************************************************************
! 划分有限元网格
!************************************************************************
ESIZE,ELEMSIZE,0, !定义单元尺寸
MAT,1 !定

义材料为1
CMSEL,,SHAFT !利用组件把轴选出来
VSWEEP,ALL !划分轴
MAT,2 !定义材料为2
ALLS
CMSEL,,PAN !利用组件把圆盘选出来
VSWEEP,ALL !划分圆盘
!************************************************************************
! 拷贝轴
!************************************************************************
ALLS
CMSEL,,SHAFT
ASLV
LSLA
KSLL
WPRO,2*N
CSYS,1
CMSEL,U,PAN
VSEL,R,LOC,Y,N,2*N
CSYS,4
VSYMM,Y,ALL,,,,0,0
WPRO,N,,
VSEL,S,LOC,Z,0,H_SH+100
VSYMM,Y,ALL,,,,0,0

ESLV
NSLE

NUMMRG,KP !捏合关键点，保证模型的连通
NUMMRG,NODE !捏合节点，保证模型的连通
!************************************************************************
! 拷贝圆盘
!************************************************************************
ALLS
WPCSYS,-1,0
CMSEL,,PAN
ASLV
LSLA
KSLL
WPRO,2*N,,
CSYS,4
VSYMM,Y,ALL,,,,0,0
WPRO,2*N
CSYS,1
VSEL,R,LOC,Y,2*N,4*N
CSYS,4
VSYMM,Y,ALL,,,,0,0
ALLS
WPCSYS,-1,0
VSEL,S,LOC,Z,0,-FLANG_H2-100
ASLV
LSLA
KSLL

ESLV
NSLE

NUMMRG,KP !捏合关键点，保证模型的连通
NUMMRG,NODE !捏合节点，保证模型的连通
!************************************************************************
! 创建新的体积组件，以便于选择
!************************************************************************
VSEL,S,LOC,Z,0,H_SH+100
CM,SHAFT,VOLU
ALLS
VSEL,S,LOC,Z,0,-FLANG_H2-100
CM,PAN,VOLU
ALLS
!************************************************************************
! 创建螺栓和螺母并划分网格
!************************************************************************
CSYS,0
CYLIND,M_BOLT/2,,M_BH1,-M_BH2,0,360,
RPR4,6,,,M_NUT,2*N,H_NUT
VGEN,,95,,,,,FLANG_H1,,,1
VGEN,2,95,,,,,-FLANG_H2-FLANG_H1-H_NUT,,0
CMSEL,U,PAN
CMSEL,U,SHAFT
VPTN,ALL
CM,B_TEMP,VOLU
VGEN,,ALL,,,RAD_DRILL,,,,,1
CSYS,1
VGEN,,ALL,,,,N,,,,1
MAT,3
ESIZE,ELEMSIZE/2,0,
VSWEEP,ALL
VGEN,4,ALL,,,,N*2,,,0
VCLEAR,B_TEMP
VDELE,B_TEMP
VGEN,,ALL,,,,-N*2,,,,1
CM,BVOLU,VOLU !创建螺栓的体积组件，以便于选择
ALLS !全选
!************************************************************************
! 建立螺栓预紧单元
!************************************************************************
psmesh,1,b100,,volu,95,0,z,0,,,,b_100
!************************************************************************
!在0号坐标系下,螺栓1(95号体积)中建立螺栓预紧单元,SECID为1,NAME为b100,预紧单元法向为Z轴,预紧节点自动建立,位置在Z方向零位置,同时将预紧单元储存于b_100单元组件中。螺栓预紧单元(pretent!ion179)不需要预先定义。
!*******************

*****************************************************
psmesh,2,b200,,volu,116,0,z,0,,,,b_200
!************************************************************************
!在0号坐标系下,螺栓2(116号体积)中建立螺栓预紧单元,SECID为2,NAME为b200,预紧单元法向为Z轴,预紧节点自动建立,位置在Z方向零位置,同时将预紧单元储存于b_200单元组件中。螺栓预紧单元(pretention179)不需要预先定义。
!************************************************************************
psmesh,3,b300,,volu,109,0,z,0,,,,b_300
!************************************************************************
!在0号坐标系下,螺栓3(109号体积)中建立螺栓预紧单元,SECID为3,NAME为b300,预紧单元法向为Z轴,预紧节点自动建立,位置在Z方向零位置,同时将预紧单元储存于b_300单元组件中。螺栓预紧单元(pretention179)不需要预先定义。
!建立螺栓预紧单元的方法有多种,都是在已经存在的单元中建立新的螺栓预紧单元。以上建立螺栓预紧单元的方法比较方便,而且容易控制。
!************************************************************************
! 创建主轴和圆盘之间的接触
!************************************************************************
CMSEL,S,SHAFT !选择轴体积组件
ASLV !选择依附于轴的面
ASEL,R,LOC,Z,0 !通过坐标位置选择轴上的接触面
CM,AS_CON,AREA !建立轴接触面组件(建立接触对时便于选择)
ALLS
CMSEL,S,PAN !选择圆盘体积组件
ASLV !选择依附于圆盘的面
ASEL,R,LOC,Z,0 !通过坐标位置选择圆盘上的目标面
CM,AP_TAR,AREA !建立圆盘目标面组件(建立接触对时便于选择)
ALLS
/COM,CONTACT PAIR CREATION - START
MAT,4 !定义摩擦系数为材料4
R,3 !定义接触实常数(ANSYS要求每个接触对必须有惟一的实常数)
REAL,3
ET,3,170 !定义三维目标单元为TARGE170
ET,4,174 !定义三维接触单元为TARGE174
KEYOPT,4,9,0 !包含初始化穿透(默认值)
!创建目标单元
CMSEL,S,AP_TAR !选择圆盘目标面组件
TYPE,3 !目标单元类型激活
NSLA,S,1 !选择目标面上所有的节点,包括边界节点
ESLN,S,0 !选择依附于这些节点的单元
ESURF,ALL !在这些单元表面形成目标单元
!创建接触单元
ALLS
CMSEL,S,AS_CON !选择轴接触面组件
TYPE,4 !接触单元类型激活
NSLA,S,1 !选择接触面上所有的节点,包括边

界节点
ESLN,S,0 !选择依附于这些节点的单元
ESURF,ALL !在这些单元表面形成接触单元
ALLS
!************************************************************************
! 创建螺母和轴以及螺母和圆盘之间的接触对
! 建立方法同上
!************************************************************************
CMSEL,S,BVOLU
ASLV
ASEL,R,LOC,Z,FLANG_H1
CM,AB1_CON,AREA
ALLS
CMSEL,S,SHAFT
ASLV
ASEL,R,LOC,Z,FLANG_H1
CSYS,1
ASEL,R,LOC,X,FH_RAD,RAD_O
CSYS,0
CM,ABS_TAR,AREA
ALLS
/COM,CONTACT PAIR CREATION - START
MAT,4
R,4
REAL,4
ET,5,170
ET,6,174
KEYOPT,5,9,0
! GENERATE THE TARGET SURFACE
CMSEL,S,ABS_TAR
TYPE,5
NSLA,S,1
ESLN,S,0
ESURF,ALL
! GENERATE THE CONTACT SURFACE
ALLS
CMSEL,S,AB1_CON
TYPE,6
NSLA,S,1
ESLN,S,0
ESURF,ALL
ALLS
/COM,CONTACT PAIR CREATION - END
!************************************************************************
! CREAT BOLT FLANG_H2 CONTACT
!************************************************************************
CMSEL,S,BVOLU
ASLV
ASEL,R,LOC,Z,-FLANG_H2
CM,AB2_CON,AREA
ALLS
CMSEL,S,PAN
ASLV
ASEL,R,LOC,Z,-FLANG_H2
CM,ABP_TAR,AREA
ALLS
/COM,CONTACT PAIR CREATION - START
MAT,4
R,5
REAL,5
ET,7,170
ET,8,174
KEYOPT,7,9,0
! GENERATE THE TARGET SURFACE
CMSEL,S,ABP_TAR
TYPE,7
NSLA,S,1
ESLN,S,0
ESURF,ALL
! GENERATE THE CONTACT SURFACE
ALLS
CMSEL,S,AB2_CON
TYPE,8
NSLA,S,1
ESLN,S,0
ESURF,ALL
ALLS
/COM,CONTACT PAIR CREATION - END
!************************************************************************
! 创建模型结束
!************************************************************************
!************************************************************************
! 求解设置
!************************************************************************
/SOLU !进入求解处理器
ALLS
LSCLEAR,ALL !清空所有载荷
ANTYPE,0 !静态分析
AUTOTS,1 !自动时间步长
NSUBST,25,100,1 !设置载荷步
OUTRES,ALL,ALL !输出所有结果
EQSLV,PCG,1E-8 !采用PCG算法,对于大模型接触算法很有效
TIME,30 !设置时间
!************************************************************************
! 设置对称边界条件
!************************************************************************
CSYS,1 !激活极坐标系
ASEL,S,LOC,Y,0 !通过坐标位置选择0度位置所有节点
DA,ALL,SYMM !建立对称边界条件
ALLS
ASEL,S,LOC,Y,90 !通过坐标位置选择90度位置所有节点
DA,ALL,SYMM !建立对称边界条件
ALLS
!************************************************************************
! LOAD STEP 1
! 在三个螺栓中施加螺栓预紧
!************************************************************************
SLOAD,1,9,LOCK,DISP,DISP_B,1,2
!在第一载荷步中对螺栓预紧SECID-1即b_100预紧单

元中,施加预紧位移为DISP_B mm,第二载荷步锁定这个位移,最终产生螺栓预紧效果。命令行中第3项9为固定数字,ANSYS要求这个数字必须大于等于9。
SLOAD,2,9,LOCK,DISP,DISP_B,1,2
SLOAD,3,9,LOCK,DISP,DISP_B,1,2
!************************************************************************
! 应用节点约束
!************************************************************************
CMSEL,S,PAN
NSLV,R,1
NSEL,R,LOC,Z,0
CSYS,1
NSEL,R,LOC,X,U_R,R_OUT
D,ALL,ALL
ALLS
SBCTRAN !转换所有载荷和约束到节点上
LSWRITE,1 !写出第一载荷步文件
!************************************************************************
! LOAD STEP 2
! 锁定螺栓预紧
!************************************************************************
LSWRITE,2 !写出第二载荷步文件
!************************************************************************
! LOAD STEP 3
! 施加轴向外载荷
!************************************************************************
NSEL,S,LOC,Z,ZMAX-1,ZMAX+10 !选取轴向节点
*get,NLOAD,NODE,,COUNT !提取节点总数
F,ALL,FZ,F_EXT/NLOAD/4 !将外载荷施加到结构上
ALLS
LSWRITE,3 !写出第三载荷步文件
LSSOLVE,1,3,1 !计算三个载荷步
!************************************************************************
! 结果后处理
!************************************************************************
/POST1 !进入通用后处理器
set,last !读取最后结果
PLNSOL,S,EQV,0,1 !输出Von Mises应力结果
!************************************************************************
! 程序结束
!************************************************************************