ANSYS谱分析实例

/COM,===========================
/COM,ANSYS地震反应谱分析示例
/COM,--Ben基于网上资料修改整理
/COM,--
/COM,--2007-12-03
/COM,===========================

/PREP7
!定义参数
B=15 !基本尺寸
A1=1000 !第一个面积
A2=1000 !第二个面积
A3=1000 !第三个面积
NMODE=10
!定义截面
ET,1,BEAM4 !二维杆单元
R,1,0.25,0.0052,0.0052,0.5,0.5
!定义材料特性
MP,EX,1,2.0E11
MP,PRXY,1,,0.3
MP,DENS,1,7.8E3
!定义节点
N,1,-B,0,0
N,2,0,0,0
N,3,-B,0,B
N,4,0,0,B
N,5,-B,0,2*B
N,6,0,0,2*B
N,7,-B,0,3*B
N,8,0,0,3*B
!定义单元
E,1,3
E,2,4
E,3,5
E,4,6
E,3,4
E,5,6
E,5,7
E,6,8
E,7,8
!边界条件
D,1,ALL,0,,2
FINISH
!静力分析
/SOLU
D,1,ALL,0,,2
SFBEAM,1,1,PRES,100000,
SFBEAM,3,1,PRES,100000,
SFBEAM,7,1,PRES,100000,
SOLVE
FINISH
ALLSEL
!模态分析
/SOLU
ANTYPE,2
MODOPT,SUBSP,10 !子空间法
MXPAND,10, , ,1
SOLVE
!存储各模态频率
*DIM,FRE,,NMODE
*DO,I,1,NMODE
*GET,FRE(I),MODE,I,FREQ ! OBTAIN MODE FREQENCY FOR MODE I
*ENDDO
FINISH
ALLSEL

!计算反应谱数据（依据规范GB50011-2001 第5.1.5条）
!地震影响系数
GRAV=9.81!重力加速度G
TG=0.35 !特性周期
AMAX=0.08!水平地震影响系数最大值
C=0.05 !阻尼比
!
*DIM,A,,NMODE
*DIM,T,,NMODE
*DO,I,1,NMODE
T(I)=1.0/FRE(I)
*ENDDO
R=0.9+(0.05-C)/(0.5+5.0*C)
P1=0.02+(0.05-C)/8
P2=1+(0.05-C)/(0.06+1.7*C)

*DO,I,1,NMODE
*IF,T(I),GE,0.0,AND,T(I),LT,0.1,THEN
A(I)=(0.45+(10.0*P2-4.5)*T(I))*AMAX*GRAV
*ELSEIF,T(I),GE,0.1,AND,T(I),LE,TG
A(I)=P2*AMAX*GRAV
*ELSEIF,T(I),GT,TG,AND,T(I),LE,5*TG
A(I)=(TG/T(I))**R*P2*AMAX*GRAV
*ELSE
A(I)=(P2*0.2**R-P1*(T(I)-5*TG))*AMAX*GRAV
*ENDIF
*ENDDO
!反应谱分析
/SOLU
ANTYPE,SPECTR
SPOPT,SPRS ! 单点反应谱
SED,1,, ! 反应方向为X轴
SVTYP,2 ! 加速度谱

! 反应谱数据
FREQ,FRE(1),FRE(2),FRE(3),FRE(4),FRE(5),FRE(6),FRE(7),FRE(8),FRE(9)
FREQ,FRE(10)
SV,,A(1),A(2),A(3),A(4),A(5),A(6),A(7),A(8),A(9)
SV,,A(10)

SRSS,0.0,DISP ! 设置震形组合方式
SOLVE
FINISH

/POST1
SET,LIST
/INPUT,,MCOM!计算反应谱工况
!***************查看反应谱结果******************
ALLSEL,ALL
FINISH