ANSYS 变压器求电感

/title, Transformer Analysis
/nopr
/com nominal
/com magnetic field in the core : Hn = (N1 I1 + N2 I2) / y = 25
/com flux density in the core : Bn =Hn / nui = 0.5 /com absolute energy in the core : nlene = HnBn/2 2xyz = 0.0125 /com absolute coenergy in the core :nlcene = BnHn 2xyz - nlene = 0.0125
/com coil1 current incremented by=0.2A
/com magnetic field in the core : H11 = Hn + N1 dI1 / y = 45
/com flux density in the core : B11 = Bn + (H11-Hn) / nui = 0.9
/com energy increment in half core : dW11= (B11-Bn)(H11-Hn)/2*xyz = 0.004 /com coil2 current incremented by=0.2A
/com magnetic field in the core : H22 = Hn + N2 dI2 / y = 65
/com flux density in the core : B22 = Bn + (Hn-H22) / nui = 1.3
/com energy increment in half core : dW22= (B22-Bn)(H22-Hn)/2*xyz = 0.016 /com both currents incremented by=0.2A
/com magnetic field in the core : H12 = Hn + (N1 dI1+N2 dI2)/ y= 85
/com flux density in the core : B12 = Bn + (Hn-H12) / nui = 1.7
/com energy increment in half core : dW12= (B12-Bn)(H12-Hn)/2*xyz = 0.036 /com inductances
/com self coil 1 : L11 ~ 2 N1^2 x z / (y nui) = 0.4
/com self coil 2 : L22 ~ 2 N2^2 x z / (y nui) = 1.6
/com mutual between coil 1 and 2 : L12 ~ 2 N1 N2 x z / (y nui) = 0.8
/com flux linkages
/com coil 1 : psi1 = 2 N1 x z B0 = 0.1 /com coil 2 : psi2 = 2 N2 x z B0 = 0.2 /com
! geometry data
n=1 ! meshing parameter
x1=0.1 ! width (x size) of coil 1
x2=0.1 ! width (x size) of coil 2
x=0.1 ! width (x size) of core
y=0.1 ! height of core, y size of window
z=0.1 ! thickness of iron in z direction
nui=50 ! absolutereluctivity of iron
n1=10 ! number of turns in coil1
n2=20 ! number of turns in coil2
! excitation data used by LMATRIX.MAC
symfac=2 ! symmetric factor for inductance computation
nc=2 ! number of coils
*dim,cur,array,nc ! nominal currents of coils
*dim,coils,char,nc ! names of coil components
cur(1)=0.2 ! nominal current of 1st coil
coils(1)='coil1' ! name of coil 1 component
cur(2)=0.025 ! nominal current of 2nd coil
coils(2)='coil2' ! name of coil 2 component
! derived auxiliary parameters
mu0=3.1415926*4.0e-7
muri=1/nui/mu0 ! relative permeability of iron
x3=x1+x2 ! x coordinate of the right of coil2
x4=x3+x ! x coordinate of middle of core (symmetry plane)
/prep7
mp,murx,1,1 ! coil1
et,1,117
mp,murx,2,1 ! coil2
mp,rsvx,2,1
et,2,117,5
!Solenoidal Formulation对导电区用AZ-VOLT自由度，对不导电区用AZ自由度．!5 -- Solid Conductors (DC Current)
!AZ, VOLT degrees of freedom: nonlinear symmetric solenoidal
!formulation applicable to static and transient analyses.
!6 -- Solid Conductors (DC Current)
!AZ, VOLT degrees of freedom: linear unsymmetricsolenoidal
!formulation applicable to harmonic analyses.
mp,murx,3,muri ! iron
et,3,117
block, 0,x1,0,y,0,z ! coil1
block,x1,x3,0,y,0,z ! coil2
block,x3,x4,0,y,0,z ! core
vglue,all
vsel,s,loc,x,x1/2
vatt,1,1,1 ! coil 1 volume attribute
vsel,s,loc,x,x1+x2/2
vatt,2,2,2 ! coil 2 volume attribute
vsel,s,loc,x,x3+x/2
vatt,3,3,3 ! iron volume attribute
vsel,all
esize,,n
vmesh,all
nsel,s,loc,x,x4 ! flux parallel Dirichlet at symm plain, x=x4,z=0,z=z
nsel,a,loc,z,0
nsel,a,loc,z,z
d,all,az,0
! homogeneous Neumann flux norm at yoke, x=0, y=0, y=y
nsel,all
! current density load on coil1
esel,s,type,,1
bfe,all,js,,,,n1*cur(1)/(x1*y)
cm,coils(1),elem
alls
nsel,s,loc,z,0
d,all,volt,0
nsel,s,loc,z,z
cp,1,volt,all !建立耦合
alls
nn1amps=node(x1,0,z)
f,nn1amps,amps,-n2*cur(2) !除了加电流密度载荷外，还可以给一个块导体加总电流F,,amps
!注：在加总电流之前需耦合节点VOLT自由度。

nsel,s,node,,nn1amps
cm,coils(2),node
nsel,all
fini
/com
/com obtain operating solution
/com
/solu
cnvtol,amps,1,1e-6
cnvtol,csg,1,1e-6
solve
fini
/post1
presol,b
lmatrix,symfac,'coil','cur','ind' ! compute inductance matrix
psi1=ind(1,3)
psi2=ind(2,3)
L11=ind(1,1)
L22=ind(2,2)
L12=ind(1,2)
/com, ******** Computed solution *********
/com
*vwrite,psi1
(' psi1 =',f10.4)
*vwrite,psi2
(' psi2 =',f10.4)
*vwrite,L11
(' L11 =',f10.4)
*vwrite,L22
(' L22 =',f10.4)
*vwrite,L12
(' L12 =',f10.4)
Finish
注：如果et,2,117,5改为et,2,117，则对绕组2电流的加载可以和绕组1一样，为esel,s,type,,2
bfe,all,js,,,,-n2*cur(2)/(x2*y)
cm,coils(2),elem
alls
其计算结果是一样的。