复杂网格划分技术

3.4 网格划分实例

复杂面模型的网格划分

1. 孔板

钢结构螺栓连接中的节点板，其板上都设有一定数量的螺栓孔，这些栓孔可能对称布置也可能不对称布置。要得到四边形映射网格必须满足其要求的条件，可对板进行适当的切分或连接。本例采用切分命令将面切成多个小面，有些可满足4 边的条件，包含曲线的面则不满足4 边的条件，可分别采用AMESH 和AMAP 命令（如用LCCAT 需要不断连接、划分、删除连接线等操作）进行映射网格划分。

示例：

! EX3.18 孔板网格划分

finish $ /clear $ /prep7

a0=300 $ b0=800 $ r0=15 ! 定义参数

blc4,,,a0,b0 $ cyl4,a0/4,b0/8,r0 ! 创建矩形面和一个圆面

agen,2,2,,,a0/2 $ agen,2,2,3,1,,b0/8 ! 复制生成其它圆面

agen,2,2,5,1,,b0*5/8 $ asel,s,,,2,9,1 ! 选择圆面

cm,a2cm,area $ allsel ! 将所选择圆面定义为组件a2cm

asba,1,a2cm ! 用矩形面减圆面，形成孔板

wprota,,-90 ! 将孔板竖向切分

*do,i,1,5 $ wpoff,,,b0/16 $ asbw,all $ *enddo

wpoff,,,b0*5/16 $ *do,i,1,5 $ wpoff,,,b0/16 $ asbw,all $ *enddo

wprota,,,90 ! 将孔板横向切分

*do,i,1,3 $ wpoff,,,a0/4 $ asbw,all $ *enddo

wpcsys,-1 $ numcmp,all

lsel,s,radius,,r0 $ lesize,all,,,8 ! 选择圆孔边界线，定义网分数为8 lsel,inve $ lesize,all,,,4 $ lsel,all ! 其余线网分数为4

et,1,82 $ mshape,0,2d $ mshkey,1 ! 定义单元类型、单元形状及网分类型

asel,u,loc,y,b0/16,b0*5/16 ! 不选择带圆孔的面

asel,u,loc,y,b0*11/16,b0*15/16 ! 不选择带圆孔的面

lsla,s$lsel,r,tan1,x ! 选择竖向线

lesize,all,50,,,,1 ! 修改这些线的网分尺寸

amesh,all $ allsel ! 划分这些面的网格

! 以下用 AMAP 划分各个5 边形面的网格

amap,21,30,31,54,62 $ amap,22,31,32,54,64 $ amap,32,29,30,62,76 $ amap,33,29,32,64,76

amap,42,34,35,76,82 $ amap,43,35,36,76,84 $ amap,41,33,34,53,82 $ amap,44,33,36,53,84

amap,19,22,23,49,64 $ amap,20,23,24,49,60 $ amap,9,21,22,64,74 $ amap,31,21,24,60,74

amap,38,26,27,74,84 $ amap,39,27,28,74,80 $ amap,37,25,26,50,84 $ amap,40,25,28,50,80

amap,17,14,15,43,59 $ amap,18,15,16,43,63 $ amap,7,13,14,59,73 $ amap,8,13,16,63,73

amap,34,18,19,73,79 $ amap,30,17,18,79,44 $ amap,35,19,20,73,83 $ amap,36,17,20,44,83

amap,15,6,7,39,63 $ amap,16,7,8,39,58 $ amap,4,6,5,63,71 $ amap,5,5,8,58,71

amap,27,10,11,71,83 $ amap,28,11,12,71,78 $ amap,26,9,10,83,40 $ amap,29,9,12,40,78

对于本例也可采用先创建部分面并划分网格，然后利用对称生成其余部分。本例旨在说明全部创建几何模型后，进行网格划分的方法和思路。

2. 角支架的网格划分

如ANSYS 帮助文件中的例子，对其结构略作改动如图所示。进行映射网格划分，但需要对几何模型进行切分或连接。

3. 大板小孔的网格划分

实际工程中经常遇到很大的板上有一很小孔，且要考虑小孔的影响。其网格划分可将整个面分为两部分，即小孔区域和远离小孔的区域，并采用过渡映射网格划分或间隔比，从而得到既满足精度要求又不浪费资源的网格。例如所示面，其中虚线部分为两部分的分界线，当然也可采用直线分割区域。

示例：

! EX3.20 大板小孔的网格划分

finish $ /clear $ /prep7

a0=100 ! 定义参数A0=100

blc4,,,a0,a0 $ cyl4,,,a0/100 $ asba,1,2 ! 创建几何模型

csys,1 $ k,50,a0/20 $ k,51,a0/20,90 ! 创建两个关键点

R1=a0/20

l,50,51 $ asbl,all,1 ! 将面分为两部分

et,1,82 $ mshape,0,2d $ mshkey,1 ! 定义单元类型及网格划分类型

lesize,5,,,8 $ lesize,1,,,10 ! 设置周向线网格数

lesize,4,,,8,5 $ lesize,6,,,8,5 $ amesh,1 ! 设置径向线的网格数及间隔