松耦合变压器apdl

FINISH
/CLEAR
/TITLE,LOOSELY COUPLED TRANSFORMER !定义工作标题
/FILNAM,Transformer_3D,1 !定义工作文件名
KEYW,MAGNOD,1 !指定磁场分析

/PREP7
ET,1,SOLID97 !砖形磁实体矢量单元
ET,2,SOLID97,3,0 !左线圈单元
*SET,HJM,9.6E-5
*SET,ZS1,40
*SET,ZS2,40
*SET,TJ,1.14E-5
R,1,HJM,ZS1,TJ,0,1,0 !设置左线圈实常数
RMORE,1,0.70
ET,3,SOLID97,3 !右线圈单元
R,2,HJM,ZS2,TJ,0,1,0 !设置右线圈实常数
RMORE,1,0.70
ET,4,SOLID97 !空气体单元
EMUNIT,MKS !MKS单位制
MP,MURX,1,1 !空气相对磁导率
MP,MURX,2,1E5
MP,MURX,3,1 !线圈相对磁导率
MP,RSVX,3,2E-7 !定义线圈电阻率

BLOCK,0,0.133,0,0.096,0,0.032 !建立非柱体部分的铁芯体

LOCAL,11,0,0.016,0.016,0
WPCSYS,,11
BLOCK,0,0.101,0,0.064,0,0.032

LOCAL,12,0,0.064,0.08,0
WPCSYS,,12
BLOCK,0,0.005,0,0.016,0,0.032

LOCAL,13,0,0.064,0,0
WPCSYS,,13
BLOCK,0,0.005,0,0.016,0,0.032
VSEL,ALL
VPLOT,ALL

VSBV,1,2,SEPO,,DELETE
NUMCMP,ALL
VPLOT,ALL
VSBV,3,1,SEPO,,DELETE
NUMCMP,ALL
VPLOT,ALL
VSBV,2,1,SEPO,,DELETE
NUMCMP,ALL
VPLOT,ALL

LOCAL,14,0,0.016,0.048,0.016,0,0,90
WPCSYS,,14
CYLIND,0.016,,0.048
LOCAL,15,0,0.117,0.048,0.016,0,0,270
WPCSYS,,15
CYLIND,0.016,,0.048
VSEL,ALL
VGLUE,ALL !体粘结
NUMCMP,ALL !压缩体积编号
VPLOT,ALL
/VIEW,,1,1,2

LOCAL,16,0,0.016,0.048,0.016,0,0,90 !左线圈建立
WPCSYS,,16
CYLIND,0.016,0.018,0.048
VSEL,S,VOLU,,5
CM,COIL1,VOLU

LOCAL,17,0,0.117,0.048,0.016,0,0,270 !右线圈建立
WPCSYS,,17
CYLIND,0.016,0.018,0.048
VSEL,S,VOLU,,6
CM,COIL2,VOLU
VSEL,ALL
VPLOT,ALL
/VIEW,,1,1,2

LOCAL,18,2,0.0665,0.048,0.016 !空气体建立
WPCSYS,,18
SPHERE,0,0.087,0,360
VSEL,ALL
VPLOT,ALL
VOVLAP,ALL !体搭接
NUMCMP,ALL !压缩体积编号
VPLOT,ALL

VSEL,S,VOLU,,1,2 !铁芯体赋特性
VSEL,A,VOLU,,5,6
VATT,2,,1
VSEL,S,VOLU,,7 !空气体赋特性
VATT,1,,4
VSEL,S,VOLU,,3 !左线圈赋特性
VATT,3,1,2
VSEL,S,VOLU,,4 !右线圈赋特性
VATT,3,2,3
VSEL,ALL
VPLOT,ALL

VSEL,ALL
SMRTSIZE,3
ESIZE,,3
MSHKEY,0 !自由网格划分
MSHAPE,1,3D !指定划分单元形状
VMESH,ALL
VSEL,ALL

!进行线圈的坐标变换（手动）

*Get,Nmax,Node,0,Num,Max !把当前最大节点赋给Nmax
N,Nmax+1,-0.1,0,0
N,Nmax+2,-0.1,0.1,0
N,Nmax+3,-0.15,0.5e-1,0
N,Nmax+4,0.250,0,0
N,Nmax+5,0.250,0.1,0
N,Nmax+6,0.288,0.5e-1,0
ET,5,CIRCU124,4,0 !定义正弦电压源单元
R,3,10 !定义电压源为10V
RMODIF,3,15,0.5E-1,1
TYPE,5
REAL,3
E,Nmax+1,Nmax+2,Nmax+3
ET,6,CIRCU124,0,0

!定义电阻单元
R,4,1 !定义电阻为1
RMODIF,4,15,-0.5E-1,2
TYPE,6
REAL,4
E,Nmax+4,Nmax+5,Nmax+6
/VIEW,,0,0,1
EPLOT

!手动输入绞线圈位置
D,Nmax+2,VOLT,0 !左电路部分约束电压自由度
D,Nmax+5,VOLT,0 !右电路部分约束电压自由度
NSEL,EXT
D,ALL,AZ,0
ESEL,S,TYPE,,2
NSLE,S
CP,1,CURR,ALL !左线圈自由度约束
CP,2,EMF,ALL
ESEL,S,TYPE,,3
NSLE,S
CP,3,CURR,ALL !右线圈自由度约束
CP,4,EMF,ALL
ALLSEL,ALL
FINISH

/SOLU
ANTYPE,HARMIC !指定谐波分析
HARFRQ,6000
NSUBST,5 !指定载荷步中需要的子步数
KBC,1 !载荷步为阶跃方式
MAGSOLV !MVP方法求解
ALLSEL,ALL
SOLVE
SAVE,LOOSELY_3D_resu.db
FINISH

/POST1
RSYS,11
/EDGE,,1 !仅显示物体的边缘
/DEVICE,VECTOR,1 !打开矢量显示模式
PLVECT,B !绘出磁通密度矢量
/VSCALE,,,1
PLVECT,H !绘出磁场强度矢量