重力坝三维仿真分析

363页

h=180
h1=100
h2=80
h3=100
gm=1000
fial=90-atan(0.75)*180/3.1415926
fia2=90-fial

!定义单元类型及材料属性
/prep7
et,1,plane42
et,2,solid65
et,3,solid45
!1号材料
mp,ex,1,2.85e10 !100米以下混凝土的材料特性
mp,prxy,1,0.167
tb,conc,1,1,9,
tbdata,,0.3,1,1.96e6,22e6 !张开剪切传递系数为0.3，抗拉强度fc=1.96e6pa，抗压强度fs=22e6pa
mp,dens,1,2400
!2号材料
mp,ex,2,2.6e10 !100米以上混凝土的材料特性
mp,prxy,2,0.167
tb,conc,2,1,9,
tbdata,,0.3,1,1.2e6,17.5e6
!张开剪切传递系数为0.3，抗拉强度fc=1.2e6pa，抗压强度fs=17.5e6pa
mp,dens,2,2400
!3号材料
mp,ex,3,2.9e10
mp,prxy,3,0.3
mp,dens,3,2600

!建立断面模型。先建立5个小面和1个大面，再进行布尔操作得到7个面的几何模型
k,1
k,2,0.9*0.75*h+0.1*h
k,3,0.1*h,0.9*h
k,4,,0.9*h
l,1,2
l,2,3
l,3,4
l,4,1
al,1,2,3,4
rectng,,0.1*h,0.9*h,h !画坝顶矩形
rectng,-1.5*h,0,-2*h,0 !坝基左面矩形
rectng,0,0.9*0.75*h+0.1*h,-2*h,0 !坝基正下方矩形
rectng,0.9*0.75*h+0.1*h,(2+0.9*0.75)*h,-2*h,0 !坝基右面矩形
rectng,-1.5*h,(2+0.9*0.75)*h,-2*h,h !总矩形
aplot
!对断面进行布尔操作。使用布尔操作中的重叠技术，即将分离的同等级对象(线段、面积、体积等)变为数个对象的连!续体，其中对象所有重叠边界所围成的区域都自成一个对象。
aovlap,all !将面单元进行粘贴布尔操作
/pnum,line,1 !打开面，线的号码开关
/pnum,area,1
nummrg,all
numcmp,all
aplot

!对面进行网格划分
!划分3号面的网格，对应于坝体的顶部
lsel,s,,,3,5,2
lesize,all,,,5
lsel,s,,,12,13,1
lesize,all,,,2
amesh,3
!划分1号面的网格，对应于坝体的下半部分
lsel,s,,,2,4,2
lesize,all,,,18
lsel,s,,,1
lesize,all,,,5
amesh,1
eplot
!划分2号面的网格，对应于坝体的正下方基岩
lsel,s,,,11
lesize,all,,,5
lsel,s,,,9,10,1
lesize,all,,,8,4
amesh,2
!划分4号面的网格
lsel,s,,,14
lesize,all,,,5,4
lsel,s,,,7
lesize,all,,,8,4
lsel,s,,,6
lesize,all,,,5,0.25
amesh,4
eplot
!划分5号面的网格
lsel,s,,,15,16,1
lesize,all,,,8,4
lsel,s,,,8
lesize,all,,,8,0.25
amesh,5
eplot
!在对剩余部分的几何面划分网格之前，需要先将相关的部分线段组合在一起，以形成由四条边构成的四边形，然后再划分网格，完成后必须将!组合线段删除。
!连接4号线和13号线，同时划分7号面的网格
lsel,s,,,4,13,9
lccat,all
lsel,s,,,19
lesize,all,,,5,4
lsel,s,,,20,21,1
lesize,all,,,20
amesh,7
eplot
!连接2号线和12号线，并划分6号面的网格
lsel,s,,,2,12,10
lccat,all
lsel,s,,,17
lesize,all,,,8,4
lsel,s,,,18,22,4
lesize,all,,,20
amesh,6
eplot
!删除前面连接的线元素
allsel
lsel,r,lcca
ldele,all

!

生成1/2体模型。先生成坝体及坝基的半个模型，此时不将面网格删除，然后生成侧面山谷的模型，此时将面网格删除。
!拉伸成坝体单元，采用SOLID65单元和1号材料，随后改变h3以上坝体的材料属性
extopt,esize,8,0 !拉伸的份数
type,2
mat,1
vext,1,3,2,,,-0.75*h !将1号和3号面拉伸成一半的模型
extopt,esize,8,0
type,3
mat,3
vext,2,,,,,-0.75*h
vext,4,5,1,,,-0.75*h
eplot

!生成侧面岩石模型
!拉伸生成大坝两侧的岩石单元
allsel
extopt,esize,5,4
extopt,aclear,1 !删除面单元
type,3
mat,3
vext,1,7,1,,,h
/pnum,mat,1
eplot

!利用映射技术生成整个大坝模型。首先定义一个局部坐标系，然后切换到局部坐标系下，先将节点映射，再映射单元，最后合并所有的节点及!单元。
local,11,0,,,-0.75*h !定义局部坐标系
csys,11 !激活局部坐标系
/psymb,cs,1 !显示不同的局部坐标系符号
dsys,11 !显示局部坐标系
nsym,z,20000,all
ensym,30000,,20000,all
nummrg,all !合并重复节点和单元
numcmp,all
eplot

!改变100m以上坝体的材料属性为2号材料
esel,s,mat,,1 !选择材料编号为1的单元
nsle,s !选择单元上的节点
nplot
nsel,r,loc,y,h3+1,h+1 !选择h3以上的单元，以便转换材料属性
nsel,r,loc,z,-0.75*h+0.1,0.75*h-0.1
nplot
esln,s
mpchg,2,all, !改变材料属性为2号材料
/replot
allsel
eplot
save,dam_model,db !保存模型文件
finish

!加载与求解
!1、静力求解
!(1)施加边界条件
/solu
csys,0
dsys,0
nsel,s,loc,x,(2+0.9*0.75)*h
nsel,a,loc,x,-1.5*h
nplot
d,all,ux
allsel
nsel,s,loc,z,h
nsel,a,loc,z,-(1+1.5)*h
nplot
d,all,uz
allsel
nsel,s,loc,y,-2*h
nplot
d,all,uy
allsel
gplot
!(2)施加外载。外载包括3部分：重力、静水压力、扬压力。在施加静水压力和扬压力时，使用梯度荷载命令。
!先选择h1高度以下的上游坝面单元为当前有效单元，然后指定梯度斜率及初始压力
acel,0,9.8 !选择上游坝面单元，施加水平静水压力
esel,s,type,,2
eplot
nsel,s,loc,x,0
nsel,r,loc,z,-1.5*h+0.1,-0.1
nsel,r,loc,y,0.1,h1-5
!若采用(h1-0.1)将导致选择过多的单元，使得施加的面分布荷载出现负数的情况
esln,s
nplot
eplot
/psf,pres,norm,2,0,1 !设定将显示压力的方向
sfgrad,pres,0,y,0,-gm !给定载荷梯度为-gm
sfe,all,2,pres,,gm*h1
/replot
!选择下游坝面单元，施加水平静水压力
allsel
esel,s,type,,2
nsle,s
eplot
local,12,0,0.9*0.75*h+0.1*h,,,fia2
csys,12
/psymb,cs,1
dsys,12
nsel,s,loc,y,0.1,h2/sin(0.75)-25
!若采用(h2/sin(0.75)-1)将导致选择过多的单元，使得施加的面分布荷载出现负数的情况
nsel,r,loc,z,-1.5*h+0.1,-0.1
nsel,u,loc,x,-1000,-2
esln,s

nplot
eplot
/psf,pres,norm,2,0,1 !设定将显示压力的方向
sfgrad,pres,0,y,0,-gm !给定载荷梯度为-gm
sfe,all,4,pres,,gm*h2
/replot
!由于在生成整体模型时采用了映射方法，导致坝底单元的单元坐标系不同，所以对坝底施加扬压力时，需要分两部分进行。
!施加上游水位h1产生的渗透压力，同时施加下游水位h2产生的浮托力
!选择第一部分坝底单元
csys,0
dsys,0
/psymb,cs,1
allsel
nsel,s,loc,y,0
nsel,r,loc,z,-135+0.1,0.1
esln,s
esel,r,type,,2
eplot
sfcum,pres,add !设置载荷是叠加的
sfe,all,5,pres,,gm*h2 !上游水位产生的渗透压力
p0=gm*h1/(0.9*0.75*h+0.1*h)
sfgrad,pres,0,x,0,-p0
sfe,all,5,pres,,gm*h1
/replot
!选择第二部分坝底单元
allsel
nsel,s,loc,y,0
nsel,r,loc,z,-270+0.1,-135-0.1
esln,s
esel,r,type,,2
eplot
p0=0
sfgrad,pres,0,x,0,-p0 !令斜率为0
sfe,all,3,pres,,gm*h2 !下游水位产生的浮托力
p0=gm*h2/(0.9*0.75*h+0.1*h)
sfgrad,pres,0,x,0,-p0
sfe,all,3,pres,,gm*h2
nsel,s,loc,y,0
esln,s
esel,r,type,,2
/replot
save,dam_static_solu,db
!(3)静力求解
allsel
outres,all,all
autots,on
nsubst,20
solve
save,dam_static_rst,db
finish


!2、反应谱分析
!(1)基本的建模和位移边界条件与静力分析是一致的。必须注意，谱分析将忽略材料的非线性，所以在此须将混凝土材料的相关设置除保留弹!性模量和泊松比外，其余都删除。
!(2)模态分析。采用子空间法进行模态分析，只提取前10阶的模态分析结果。
/solu
antype,modal
modopt,subsp,10
solve
save,dam_dynamic_rst11,db
finish
!(3)计算反应谱值。根据图10-16的10阶固有频率值以及表达式(10-3)，可计算出对应于各阶频率的反应谱谱值，如表10-1所示。
!(4)反应谱分析
/solu
antype,spectr
spopt,sprs,10,yes
svtyp,2
sed,1,1,
freq,0.3444,0.3502,0.3546,0.3739,0.4175,0.4613,0.5114,0.5121,0.5811,0.5837
sv,1.226,1.2079,1.1945,1.1389,1.0312,0.9427,0.859,0.858,0.7657,0.7627
solve
save,dam_dynamic_rst2,db
finish
!(5)模态扩展
/solu
antype,modal
expass,on
mxpand,10,,,yes,0.005
solve
finish
!(6)合并模态。响应谱分析得到的是系统各阶模态下的位移响应谱，而这些模态响应之间存在着耦合，且所有模态的最大值不可能同时出现，!所以需要对其进行组合，本例采用平方和，再求平方根的组合方法。
/solu
antype,spectr
srss,0.15,disp
solve
save,dam_dynamic_rst4,db
finish

!计算结果分析
!1、静力求解结果
/post1
esel,s,type,,2
set,last
plnsol,u,x,0,1 !位移变形图
plnsol,u,y,0,1
plnsol,epto,1,0,1 !画第一主应变
plnsol,s,1,0,1 !画第一主应力
!坝体混凝土开裂情况
!显示开裂位置
/device,vector,1
plcrack,0,0
!ansys可以显示混凝土单元具体的开裂情况，包括裂缝的张开、闭合、压碎等。查看在各个积分点上的

开裂情况，其中53、60、67、74、81、
!88、95、102代表着solid65单元1到8个积分点。
etable,11,nmisc,53 !将1号积分点上的单元状态值赋给变量11
etable,22,nmisc,60
etable,33,nmisc,67
etable,44,nmisc,74
etable,55,nmisc,81
etable,66,nmisc,88
etable,77,nmisc,95
etable,88,nmisc,102
!绘制各个单元表，可以发现在开裂区域，状态变量的值从中心处的2逐渐增加到未开裂区域的16。其中，2代表单元只在第一方向上张开，其他!的状态变量值的具体含义请参考ansys单元手册。
pletab,11,avg
pletab,22,avg
pletab,33,avg
pletab,44,avg
pletab,55,avg
pletab,66,avg
pletab,77,avg
pletab,88,avg
!2、动力性分析结果
!(1)大坝位移变形图
/post1
/input,,mcom
esel,s,type,,2
eplot
set,first
plnsol,u,sum,1,1 !组合过后的第一阶(对应于原来的第一阶频率)的变形图，既有y方向的竖向变形，也有顺流x方向的变形
set,next
plnsol,u,sum,1,1 !组合过后的第二阶(对应于原来的第三阶频率)的变形图，主要是沿y方向的竖向变形
set,next
plnsol,u,sum,1,1 !组合过后的第三阶(对应于原来的第五阶频率)的变形图，主要体现了x方向的变形
!(2)应力、应变分布
set,first
plnsol,s,1,0,1 !此图表明第一阶最大的第一主应力将出现在上游坝的两侧处
plnsol,epto,1,0,1 !此图表明第一阶最大的第一主应变将出现在上游坝的两侧处，此处的混凝土将首先开裂
set,next
plnsol,s,1,0,1 !此图表明第四阶最大的第一主应力将出现在下游坝的两侧处
plnsol,epto,1,0,1 !此图表明第四阶最大的第一主应变将出现在下游坝的两侧处，此处的混凝土将首先开裂
!(3)坝顶节点位移随时间的变化
/post26
csys,0
nsel,s,loc,y,h
nsel,r,loc,z,-0.75*h
nsel,r,loc,x,0
nplot
nsol,2,1466,u,x,nux
nsol,3,1466,u,y,nuy
nsol,4,1466,u,z,nuz
xvar,1
plvar,2,3,4