ANSYS磁-结构分析命令流

finish
/clear
/title,Force Calculation of Two Opposite Electrodes
/prep7
emunit,mks !定义电磁单位为国际标准单位，u0=4pi*e-7henries/meter
!********************************************
! 定义单元类型*
!********************************************
et,1,97
!********************************************
! 定义材料*
!********************************************
mp,dens,3,7770 !材料密度
mp,prxy,3,0.3 !材料泊松比
mp,ex,3,2e5 !材料弹性模量
mp,dens,2,7770
mp,prxy,2,0.3
mp,ex,2,2e5

mp,murx,1,1 !空气的渗透率
mp,murx,2,1000 !铁块的磁导率
mp,murx,3,2000 !电枢的磁导率
mp,murx,4,1 !线圈的渗透率（磁导率），1为各向同性
mp,murx,5,1 !线圈的渗透率（磁导率），1为各向同性
mp,murx,6,1 !线圈的渗透率（磁导率），1为各向同性
mp,murx,7,1 !线圈的渗透率（磁导率），1为各向同性

w1=0.5
h1=0.1
t1=0.1
n=650 ! Number of coil turns 线圈匝数
i=1.0 ! Current per turn 当前每转
hc=h1
tc=t1
acoil=tc*hc ! Cross-section area of coil (cm**2) 线圈截面积(cm**2)
jdens=n*i/acoil ! Current density (A/cm**2) 电流密度(A /厘米* * 2)
!********************************************
!* 建立模型*
!********************************************
blc4,,,w1,h1,t1
blc4,w1/3,,w1/3,3*h1,t1
blc4,-w1,-w1,3*w1,2*w1+3*h1,t1
wpoffs,,2*h1
blc4,,,w1,h1,t1
alls
vovlap,all
numcmp,volu
!********************************************
!建立材料属性
!********************************************
vSEL,S,volu,,8 ! Assign attributes to coil 为空气分配属性
vATT,1,1,1,0
vSEL,S,volu,,1 ! Assign attributes to coil 为线圈分配属性
vATT,4,1,1,0
vSEL,S,volu,,2
vATT,5,1,1,0
vSEL,s,volu,,5
vATT,6,1,1,0
vSEL,s,volu,,6
vATT,7,1,1,0
vSEL,S,volu,,7 ! Assign attributes to armature 为电枢分配属性
vATT,3,1,1,0
vSEL,S,volu,,3 ! Assign attributes to backiron 为铁块分配属性
vSEL,A,volu,,4
vATT,2,1,1,0

/PNUM,MAT,1 ! Turn material numbers on 开启材料编号
ALLSEL,ALL
vPLOT
!********************************************
!划分网格
!*******************************************

*
esize,0.04
vsweep,ALL ! Mesh all areas 划分所有领域
!********************************************
!建立载荷
!********************************************
ESEL,S,MAT,,3 ! Select armature elements 选择电枢元素
CM,'ARM',ELEM ! Define armature as a component 将电枢定义为组件
FMAGBC,'ARM' ! Apply force boundary conditions to armature 对电枢施加力边界条件 将力和力矩边界条件应用于元件
!********************************************
!求解
!********************************************
/SOLU

ESEL,S,MAT,,4 ! Select coil elements 选择线圈元素
BFE,ALL,JS,1,,,jdens/0.01**2 ! Apply current density (A/m**2) 施加电流密度(A/m**2)
ESEL,S,MAT,,5 ! Select coil elements 选择线圈元素
BFE,ALL,JS,1,,,jdens/0.01**2 ! Apply current density (A/m**2) 施加电流密度(A/m**2)
ESEL,S,MAT,,6 ! Select coil elements 选择线圈元素
BFE,ALL,JS,1,,,jdens/0.01**2 ! Apply current density (A/m**2) 施加电流密度(A/m**2)
ESEL,S,MAT,,7 ! Select coil elements 选择线圈元素
BFE,ALL,JS,1,,,jdens/0.01**2 ! Apply current density (A/m**2) 施加电流密度(A/m**2)

nsel,s,loc,x,-0.5 ! Select exterior nodes 选择外部节点
nsel,a,loc,y,-0.5
nsel,a,loc,x,1
nsel,a,loc,y,0.8
D,ALL,az,0 ! Set potentials to zero (flux-parallel) 将电位设为零(磁通并联)
D,ALL,ax,0
D,ALL,ay,0
ALLSEL,ALL
MAGSOLV ! Solve magnetic field 解决磁场
save
!********************************************
!后处理
!********************************************
/POST1
PLF2D,27,0,10,1 !显示磁力线
FMAGSUM ! Summarize magnetic forces 总结磁力
PLVECT,B,,,,VECT,ELEM,ON ! Plot flux density as vectors 绘制通量密度作为矢量
save



!********************************************
!耦合过程（替换单元，重新划分网络并与原网络保持一致）
!********************************************
finish
/clear
/PREP7
et,1,62,0
emunit,mks
mp,dens,3,7770
mp,prxy,3,0.3
mp,ex,3,2e5
mp,dens,2,7770
mp,prxy,2,0.3
mp,ex,2,2e5
mp,murx,1,1
mp,murx,2,1000
mp,murx,3,2000
mp,murx,4,1
mp,murx,5,1
mp,murx,6,1
mp,murx,7,1
w1=0.5
h1=0.1
t1=0.1
blc4,,,w1,h1,t1
blc4,w1/3,,w1/3,3*h1,t1
blc4,-w1,-w1,3*w1,2*w1+3*h1,t1
wpoffs,,2*h1
blc4,,,w1,h1,t1
alls
vovlap,all
numcmp,volu
vSEL,S,volu,,8
vATT,1,1,1,0
vSEL,S,volu,,1
vATT,4,1,1,0
vSEL,S,volu,,2
vATT,5,1,1,0
vSEL,s,volu,,5
vATT,6,1,1,0
vSEL,s,volu,,6
vATT,7,1,1,0
vSEL,S,volu,,7
vATT,3,1,1,0
vSEL,S,volu

,,3
vSEL,A,volu,,4
vATT,2,1,1,0
ALLSEL,ALL
esize,0.04
vsweep,ALL
!********************************************
!求解
!********************************************
/solu
LSCLEAR,all
LDREAD,forc,1,,,,,rmg !读入之前计算的磁力大小
aSEL,S,,,54
nsla
d,all,all !定义结构边界条件
time,1
nsubst,1
alls
solve
/post1
plnsol,u,sum